Öffnen Sie eine URL in Chrome Canary als inkognito

Ich verwende derzeit dieses Automator-AppleScript, um einen Dienst zum Öffnen einer URL mit Chrome Canary im Inkognito-Modus zu erstellen

on run {input}
    set theURL to input
    if application "Google Chrome Canary" is running then
        tell application "Google Chrome Canary" to make new window with properties {mode:"incognito"}
    else
        do shell script "open -a /Applications/Google\\ Chrome\\ Canary.app --args {URL:theURL} --incognito"
    end if

    tell application "Google Chrome Canary" to activate
end run

Google Chrome Canary wird mit einem neuen Fenster gestartet, die URL wird jedoch nicht geladen. Was vermisse ich?

Danke.

Ich habe Google Chrome Canary nicht installiert, aber ich habe Google Chrome installiert, und da Sie nicht gezeigt haben, wie on run {input}die Eingabe tatsächlich empfangen wird , wird das, was ich präsentiere, in AppleScript Editor ausgeführt. Sie sollten es jedoch in Ihre Sprache übersetzen können Verwendung mit Google Chrome Canary in Automator.

Die folgenden AppleScript- Codebeispiele machen das, was Sie versuchen, obwohl Sie in Google Chrome nicht Google Chrome Canary verwenden. Ändern Sie jedoch die Instanzen von Google Chrome nach Bedarf in Google Chrome Canary, und es sollte funktionieren, da die Beispiele wie getestet funktionieren.

In diesem ersten Beispiel wird der do shell script Befehl im else Block verwendet :

set theURL to "http://apple.stackexchange.com/questions/270413/open-a-url-in-chrome-canary-as-incognito"

if application "Google Chrome" is running then
    tell application "Google Chrome"
        activate
        make new window with properties {mode:"incognito"}
        open location theURL
    end tell
else
    do shell script "open -a 'Google Chrome' --args --incognito " & quoted form of theURL
end if

tell application "Google Chrome" to activate

Hinweis: Wenn in einem Run Applescript verwendet Aktion in Automator können Sie nicht verwenden müssen , quoted form ofmit theURL, so dass der letzte Teil des do shell script Befehls in diesem Fall wird nur sein:
& theURL

Dieses zweite Beispiel verzichtet auf die Verwendung des do shell script Befehls im else Block :

set theURL to "http://apple.stackexchange.com/questions/270413/open-a-url-in-chrome-canary-as-incognito"

if application "Google Chrome" is running then
    tell application "Google Chrome"
        activate
        make new window with properties {mode:"incognito"}
        open location theURL
    end tell
else
    tell application "Google Chrome"
        activate
        -- close window 1   # Uncomment this line if you want the normal window that opens first to be closed.
        make new window with properties {mode:"incognito"}
        open location theURL
    end tell
end if