Applescript: So laden Sie verknüpfte Dateien von der Google Chrome-Seite herunter

Ich muss einen Weg finden, verknüpfte Dateien auf einer Webseite in Google Chrome herunterzuladen.

Ich bin der Grafiker in der Firma, für die ich arbeite, und ich habe ein Formular "Projektbeschreibung", das andere Mitarbeiter ausfüllen, wenn sie Designarbeiten anfordern müssen. In dem Formular können sie Dateien hochladen, die sich auf das Projekt beziehen (z. B. Skizzen oder Textdateien). Ich habe eine Automator-App, die das Projekt vom Erstellen eines Ordnersystems für das Projekt über das Herunterladen des Formulars als PDF bis zum Herunterladen aller angehängten Dateien einrichtet. Es funktioniert jedoch nur in Safari und ich verwende Chrome. Bisher habe ich alles umgestellt und arbeite in Chrome EXCEPT für die Dateidownloads.

Kann mir jemand helfen, herauszufinden, wie ich dieses Chrome ausführen kann?

Hier ist das Skript "Dateien herunterladen", das in Safari funktioniert:
(Ignorieren Sie das '\' in Applescript \ 's. Ohne sie erhielt ich eine seltsame Syntaxhervorhebung.)

-- DOWNLOAD ATTACHED FILES
tell application "Safari"
activate

set num_links to (do JavaScript "document.links.length" in document 1)
repeat with i from 0 to num_links - 1
    tell application "Safari" to set this_link to do JavaScript "document.links[" & i & "].href" in document 1
    set {ASTID, AppleScript\'s text item delimiters} to {AppleScript\'s text item delimiters, "/"}
    set fName to last text item of this_link
    set AppleScript\'s text item delimiters to ASTID
    try
        do shell script "curl -L -o " & quoted form of (destinationFolder & fName) & space & this_link
    end try
end repeat

end tell

Wenn ich beide Exemplare von "Safari" durch "Google Chrome" ersetze und versuche, es auszuführen, erhalte ich eine Syntaxfehlermeldung mit der folgenden Meldung: Expected “,” but found identifier. und hat die JavaScript in dem set num_links Zeile hervorgehoben.

Ich habe es bekommen, um es unter OSX richtig zu kompilieren

-- DOWNLOAD ATTACHED FILES
tell application "Google Chrome"
    activate
    set num_links to execute front window's active tab javascript "document.links.length"
    repeat with i from 0 to num_links - 1
        tell application "Google Chrome" to set this_link to execute front window's active tab javascript "document.links[" & i & "].href"
        set {ASTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "/"}
        set fName to last text item of this_link
        set AppleScript's text item delimiters to ASTID
        try
            do shell script "curl -L -o " & quoted form of (destinationFolder & fName) & space & this_link
        end try
    end repeat
end tell