Überprüfen Sie, ob ein Benutzer in einer SQL Server-Datenbank vorhanden ist

Ich arbeite mit SQL Server 2012. Ich möchte überprüfen, ob ein Benutzer vorhanden ist, bevor ich ihn einer Datenbank hinzufüge.

Das habe ich getestet:

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT name 
                FROM [sys].[server_principals]
                WHERE name = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Dieser Code wird SELECT name FROM [sys].[server_principals]jedoch nicht zurückgegeben, wenn dieser Benutzer in vorhanden ist MyDatabase.

Wie kann ich überprüfen, ob ein Benutzer in existiert MyDatabase?

Verwenden Sie sys.database_principalsanstelle von sys.server_principals.

Die endgültige Abfrage würde also so aussehen (Berücksichtigung des Benutzerfilters):

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT [name]
                FROM [sys].[database_principals]
                WHERE [type] = N'S' AND [name] = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Ich benutze SUSER_ID () und USER_ID () für diese Art von Dingen:

-- Check SQL Server Login
IF SUSER_ID('SomeLogin') IS NULL
    CREATE LOGIN SomeLogin WITH PASSWORD = 'SomePassword';

-- Check database user
IF USER_ID('SomeUser') IS NULL
    CREATE USER SomeUser FOR LOGIN SomeLogin;

Weitere Verfeinerung, da dies zu einer optimalen Lesbarkeit führen würde.

USE [MyDatabase]
GO

IF DATABASE_PRINCIPAL_ID('IIS APPPOOL\MyWebApi AppPool') IS NULL
BEGIN
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
END
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Wenn Sie resistered-Server verwenden, können Sie mehrere Server gleichzeitig prüfen und ein true / false zurückgeben mit:

SELECT @@servername,    
    CASE 
        WHEN EXISTS(SELECT name FROM sys.database_principals WHERE name = 'LoginName') THEN 1 
        ELSE 0 
    END AS YesNo