So öffnen Sie mit "o" von dired / ibuffer in einen anderen Frame

Ich habe zwei Fenster geöffnet und vertikal geteilt (Einzelbild):

A) enthält meine Arbeit
B) enthält entweder dired oder ibuffer.

Ich möchte in der Lage sein, zu einer Datei / einem Puffer in Bereich B zu navigieren und auf "o" zu klicken, um sie in Bereich A zu öffnen. Ist dies möglich? Im Moment erstellt emacs einen neuen Bereich im unteren Bereich von Bereich A, um die Datei zu öffnen.

Bearbeiten: Gemäß der Benutzerrechtsliste tritt das oben beschriebene Verhalten auf, wenn der Rahmen groß ist. Dies scheint bei mir der Fall zu sein, da sich Emacs jetzt, da ich zu Hause bin (nicht auf einem externen Monitor, kleinerer Rahmen), so verhalten, wie ich es mir wünsche. Jetzt stellt sich die Frage: Kann ich verhindern, dass Emacs ein neues Fenster öffnen, wenn der aktuelle Frame groß ist?

Hier sind vier (4) Beispiele für benutzerdefinierte display-bufferFunktionsfamilien, die individuell auf die speziellen Bedürfnisse eines Benutzers zugeschnitten werden können - siehe oben ; unten ; links ; rechts - und hier sind vier (4) interactiveFunktionen zum Anzeigen der Datei oder des Verzeichnisses der aktuellen Zeile eines dired-modePuffers. Es gibt nur drei Bedingungen: (a) Wenn bereits ein Fenster mit dem Zielpuffer vorhanden ist, wählen Sie ihn aus. (b) Wenn ein Fenster in der gewünschten Richtung verfügbar ist, verwenden Sie es. (c) Der Haken ist, ein neues Fenster in die gewünschte Richtung zu erstellen, wenn die anderen Bedingungen nicht erfüllt sind.

Verwendungszweck:

M-x dired-display-above

M-x dired-display-below

M-x dired-display-left

M-x dired-display-right

Es sind so viele Tastenkombinationen bereits eingebaut dired-modeund dired+, dass ich es nicht wage, meine eigenen zu erfinden. Dem Benutzer steht es frei, seine eigenen Tastaturkürzel zu wählen, was den Rahmen dieses begrenzten Beispiels sprengt.

Dem Benutzer steht es frei, der Beispielfunktionsfamilie zusätzliche Bedingungen hinzuzufügen display-buffer, um mehr Situationen zu bewältigen - z. B. mehr Fenster als nur ein paar.

(defun my-display-buffer-below (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'below))
          (t
            (split-window (selected-window) nil 'below)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-above (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'above))
          (t
            (split-window (selected-window) nil 'above)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-left (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'left))
          (t
            (split-window (selected-window) nil 'left)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun my-display-buffer-right (buffer alist)
"Doc-string."
  (let (
      (window
        (cond
          ((get-buffer-window buffer (selected-frame)))
          ((window-in-direction 'right))
          (t
            (split-window (selected-window) nil 'right)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun dired-display-above ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-above buffer nil)))

(defun dired-display-below ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-below buffer nil)))

(defun dired-display-left ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-left buffer nil)))

(defun dired-display-right ()
"Doc-string."
(interactive)
  (let* (
      (file-or-dir (dired-get-file-for-visit))
      (buffer (find-file-noselect file-or-dir)))
    (my-display-buffer-right buffer nil)))

BEARBEITEN: Hier ist eine etwas ausgefeiltere / unterhaltsamere Implementierung des obigen Konzepts, die dem Benutzer die Möglichkeit gibt, dieses nicht interaktiv oder interaktiv zu verwenden . zB M-x dired-display-buffer- wo der Benutzer aufgefordert wird, ein Verzeichnis auszuwählen, wenn er nicht mit der Maus über eine Datei fährt dired-mode, und eine Anzeigerichtung zu wählen (links, rechts, oben, unten).

(defun my-display-buffer (buffer-or-name alist direction &optional size pixelwise)
"BUFFER:  The buffer that will be displayed.
ALIST:  See the doc-string of `display-buffer' for more information.
DIRECTION:  Must use one of these symbols:  'left 'right 'below 'above
SIZE:  See the doc-string for `split-window'.
PIXELWISE:  See the doc-string for `split-window'.
There are three possibilities:
-  (1) If a window on the frame already displays the target buffer,
then just reuse the same window.
-  (2) If there is already a window in the specified direction in relation
to the selected window, then display the target buffer in said window.
-  (3) If there is no window in the specified direction, then create one
in that direction and display the target buffer in said window."
  (let* ((buffer
           (if (bufferp buffer-or-name)
             buffer-or-name
             (get-buffer buffer-or-name)))
         (window
           (cond
             ((get-buffer-window buffer (selected-frame)))
             ((window-in-direction direction))
             (t
               (split-window (selected-window) size direction pixelwise)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

(defun dired-display-buffer (&optional direction alist)
"Display a dired-mode buffer or a file underneath point in a dired-mode buffer."
(interactive)
  (let* ((file-or-dir (or (and (eq major-mode 'dired-mode) (dired-get-file-for-visit))
                               (read-directory-name "Directory:  ")))
         (buffer (find-file-noselect file-or-dir))
         (direction
           (if direction
             direction
             (let ((char (read-char-exclusive (concat
                      "["
                      (propertize "l" 'face '(:foreground "red"))
                      "]"
                      (propertize "eft" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "r" 'face '(:foreground "red"))
                      "]"
                      (propertize "ight" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "a" 'face '(:foreground "red"))
                      "]"
                      (propertize "bove" 'face '(:foreground "blue"))
                      " | ["
                      (propertize "b" 'face '(:foreground "red"))
                      "]"
                      (propertize "elow" 'face '(:foreground "blue"))))))
                (cond
                  ((eq char ?l)
                    'left)
                  ((eq char ?r)
                    'right)
                  ((eq char ?a)
                    'above)
                  ((eq char ?b)
                    'below)
                  ;;; FIXME:  @lawlist may add a loop similar to `org-capture'
                  ;;; whereby a new `read-char-exclusive' will be initiated if
                  ;;; a user did not initially choose a valid option (l/r/a/b).
                  (t
                    (let ((debug-on-quit nil)
                          (msg (concat "dired-display-buffer:  "
                                       "You did not select l/r/a/b "
                                       "-- exiting.")))
                      (signal 'quit `(,msg)))))))))
    (my-display-buffer buffer alist direction)))

Ihre Frage ist unklar und daher besteht die Gefahr, dass sie geschlossen wird. Haben Sie zwei Frames oder einen einzelnen Frame mit zwei Emacs-Fenstern? Was auch immer sie sind, wenn es zwei gibt, ist jeder von ihnen vertikal geteilt? Und was meinst du mit "vertikal teilen"? Was meinst du mit einer "Scheibe"? Was meinst du mit "es" in "in Fenster A geöffnet haben"?

Eine wilde Vermutung ist, dass Sie einen einzelnen Emacs-Frame haben, der in zwei Emacs-Fenster A und B aufgeteilt ist, wobei Fenster A über Fenster B, Fenster B ausgewählt ist und Fenster B einen Dired-Puffer anzeigt.

oist standardmäßig an gebunden dired-find-file-other-window. Wenn die obige wilde Vermutung richtig ist, sollte oein Dateiname in B in A geöffnet werden. Dies wird beim Starten von Emacs ohne Init-Datei angezeigt : emacs -Q. Siehst du das nicht

Wenn dies nicht der Fall ist, beschreiben Sie bitte Schritt für Schritt klar, was Sie tun emacs -Q.

HINWEIS : Die folgenden Variablen sind global , was bedeutet, dass sie sich auch auf andere Funktionen auswirken dired-find-file-other-window. Der Benutzer möchte die betreffende Funktion möglicherweise beraten , um andere Funktionen nicht global zu beeinflussen. [Dieser Autor überlässt diese Option jedoch einem anderen Forumsteilnehmer.] Alternativ gibt es eine andere Antwort, die dieser Autor veröffentlicht hat und die benutzerdefinierte Funktionen enthält, die verwendet werden können, um nichts anderes zu beeinflussen.

Die Variable split-width-thresholdhat eine Dokumentzeichenfolge, die Folgendes angibt:

Minimum width for splitting windows sensibly.
If this is an integer, ‘split-window-sensibly’ may split a window
horizontally only if it has at least this many columns.  If this
is nil, ‘split-window-sensibly’ is not allowed to split a window
horizontally.

Wenn Sie in der .emacsDatei Folgendes einstellen, wird der gewünschte Effekt erzielt. Der Benutzer kann den Wert auch auf eine höhere Zahl einstellen. Der Standardwert ist 160

(setq split-width-threshold nil)

Hier ist ein Link zum entsprechenden Abschnitt im Handbuch:

https://www.gnu.org/software/emacs/manual/html_node/emacs/Window-Choice.html

Siehe auch die zugehörige Variable split-height-thresholdmit dem Standardwert 80

Die Dokumentzeichenfolge lautet:

Minimum height for splitting windows sensibly.
If this is an integer, `split-window-sensibly' may split a window
vertically only if it has at least this many lines.  If this is
nil, `split-window-sensibly' is not allowed to split a window
vertically.  If, however, a window is the only window on its
frame, `split-window-sensibly' may split it vertically
disregarding the value of this variable.