Wie kann ich eine Vorschau von TeX-Formeln in beliebigen Modi inline anzeigen?

Wie kann ich TeX-Vorschauen in anderen Modi als AUCTeX oder org-Modus erhalten? Ich würde gerne TeX-Gleichungen in Jabber, Erc und Markdown sehen. Wenn ich jemals zu Emacs wechseln sollte, um eine E-Mail zu erhalten, würde ich dort vermutlich auch gerne Vorschauen sehen.

Ich habe versucht, AUCTeX preview-latex wiederzuverwenden, bin jedoch gescheitert und habe aufgegeben.

Der Org-Modus bietet ebenfalls die gleiche Funktion . Es stellte sich heraus, dass weechat es geschafft hat, es wiederzuverwenden, um automatisch die Latex-Vorschau anzuzeigen .

Ich habe den Vorschau-Teil von weechat in einer separaten Datei extrahiert, die Sie auf diesem Repo erhalten können . Es ist auch als pxPaket auf MELPA erhältlich (ich habe es gerade eingereicht).

Es gibt 4 Einstiegspunkte, die interaktiv aufgerufen werden können:

• px-preview: Alle Latexfragmente im aktuellen Puffer rendern.
• px-preview-region: Fragmente in der Region rendern.
• px-remove: Alle Vorschaubilder aus dem aktuellen Puffer entfernen (Text wiederherstellen).
• px-toggle: Anzeige der Vorschau im aktuellen Puffer umschalten.

Solange der org-mode previewer funktioniert, sollte dieser funktionieren.

Da der Code immer noch ziemlich klein ist, werde ich ihn unten einfügen, aber bitte installieren Sie das Paket oder verwenden Sie das Repo.

;;; px.el --- preview inline latex -*- lexical-binding: t -*-

;; Most of this code comes from weechat-latex.el which in turn uses
;; org-mode previewer.

;; Copyright (C) 2014 Aurélien Aptel <[email protected]>
;; Copyright (C) 2013 Rüdiger Sonderfeld <[email protected]>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(require 'org)

(defvar px-temp-file-prefix "px-"
  "Prefix for temporary files.")

(defvar px-temp-directory-prefix "px-"
  "Prefix for temporary directory.")

(defvar px-image-program org-latex-create-formula-image-program
  "Program to convert LaTeX fragments.
See `org-latex-create-formula-image-program'")

(defvar px-temp-dir nil
  "The temporary directory used for preview images.")

(defun px--create-preview (at)
  "Wrapper for `org-format-latex'.
The parameter AT should be nil or in (TYPE . POINT) format.  With TYPE being a
string showing the matched LaTeX statement (e.g., ``$'') and POINT being the
POINT to replace.  If AT is nil replace statements everywhere."
  (org-format-latex px-temp-file-prefix
                    px-temp-dir
                    'overlays
                    "Creating images...%s"
                    at 'forbuffer
                    px-image-program))

(defun px--set-temp-dir ()
  "Set `px-temp-dir' unless it is already set."
  (unless px-temp-dir
    (setq px-temp-dir
          (make-temp-file px-temp-directory-prefix
                          'directory))))

(defun px-preview ()
  "Preview LaTeX fragments."
  (interactive)
  (save-excursion
    (let ((inhibit-read-only t))
      (px--set-temp-dir)
      (org-remove-latex-fragment-image-overlays)
      (px--create-preview nil))))

(defun px-preview-region (beg end)
  "Preview LaTeX fragments in region."
  (interactive "r")
  (let* ((math-regex (assoc "$" org-latex-regexps))
         (regex (nth 1 math-regex))
         (n (nth 2 math-regex))
         matches)
    (save-excursion
      (goto-char beg)
      (while (re-search-forward regex end t)
        (setq matches (cons (cons "$" (match-beginning n)) matches)))
      (let ((inhibit-read-only t))
        (px--set-temp-dir)
        (dolist (i matches)
          (px--create-preview i))))))


(defun px-remove ()
  "Remove LaTeX preview images."
  (interactive)
  (let ((inhibit-read-only t))
    (org-remove-latex-fragment-image-overlays)))

(defun px-is-active? ()
  "Are LaTeX Previews currently displayed?"
  org-latex-fragment-image-overlays)

(defun px-toggle ()
  "Toggle display of LaTeX preview."
  (interactive)
  (if (px-is-active?)
      (px-remove)
    (px-preview)))


(provide 'px)

Es gibt auch das, texfrag.elwas bei Doxy-Kommentaren sofort funktioniert prog-mode.

Sie können texfrag.elvon melpa-stablevia installieren M-x package-install RET texfrag RET.

Führen Sie aus M-x texfrag-mode RET, um die Vorschau zu aktivieren. Sie erhalten das Vorschau-Menü mit allen Elementen des AUCTeX-Vorschau-Pakets.

Beachten Sie, dass dies texfragauch für die Bearbeitung von HTML-Quellcode, eww und org-Modus funktioniert.