Wie rufe ich Dokumentzeichenfolgen aus Funktionen und Variablen ab?

Ich versuche, eine Funktion zu schreiben, die die Dokumentzeichenfolgen von allen Sexps in einer übereinstimmenden Datei abruft (def.*).

Ich möchte sowohl Funktionen / Makros als auch definierte Variablen abrufen können. Für Variablen möchte ich die Dokumentzeichenfolge, für alle Funktionen möchte ich auch die Argumentlisten.

Wenn das Ziel darin besteht, Informationen über Funktionen und Variablen zu erhalten, die sich bereits in der Umgebung befinden :

• Dokumente zu Funktionen und Makros finden Sie in der documentationFunktion.

• Verwenden Sie für variable Dokumentzeichenfolgen documentation-property; zum Beispiel:

  (documentation-property
   'user-init-file 'variable-documentation)
  

• Informationen zur Funktionsarität und zur Argumentliste finden Sie in dieser Emacs.SE-Frage , der Antwort und den Kommentaren zur Frage.

(Ich fand dies durch Drücken C-h k C-h fund Überfliegen des Quellcodes von describe-function(dasselbe für variable Dokumentzeichenfolgen, aber Lernen describe-variable).)

Um eine Emacs Lisp-Quellcodedatei zu analysieren, unter der Annahme, dass das Ziel darin besteht, Informationen über def.*Formulare der obersten Ebene zu erhalten , können Sie Folgendes tun.

(defun get-defun-info (buffer)
  "Get information about all `defun' top-level sexps in a buffer
BUFFER. Returns a list with elements of the form (symbol args docstring)."
  (with-current-buffer buffer
    (save-excursion
      (save-restriction
        (widen)
        (goto-char (point-min))
        (let (result)
          ;; keep going while reading succeeds
          (while (condition-case nil
                     (progn
                       (read (current-buffer))
                       (forward-sexp -1)
                       t)
                   (error nil))
            (let ((form (read (current-buffer))))
              (cond
               ((not (listp form))      ; if it's not a list, skip it
                nil)
               ((eq (nth 0 form) 'defun) ; if it's a defun, collect info
                (let ((sym (nth 1 form))
                      (args (nth 2 form))
                      (doc (when (stringp (nth 3 form)) (nth 3 form))))
                  (push (list sym args doc) result))))))
          result)))))

Dies kann leicht erweitert werden defvar, defconstusw.

Um das defunErscheinen in Formularen der obersten Ebene zu handhaben , müsste man in diese Formulare absteigen , möglicherweise unter Verwendung von Rekursion.