Wie installiere ich Emacs-Pakete automatisch, indem ich eine Liste von Paketnamen angebe?

Ich verwende package, um meine Emacs-Erweiterungen zu verwalten. Um meine Emacs-Einstellungen auf verschiedenen Computern zu synchronisieren, möchte ich eine Liste von Paketnamen in der .emacsDatei angeben und dann packagedie Pakete automatisch suchen und installieren, sodass ich sie nicht manuell durch Aufrufen installieren muss M-x package-list-packages. Wie geht das?

; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))

Basierend auf Kommentaren von Profpatsch und Antworten unten:

(defun ensure-package-installed (&rest packages)
  "Assure every package is installed, ask for installation if it’s not.

Return a list of installed packages or nil for every skipped package."
  (mapcar
   (lambda (package)
     ;; (package-installed-p 'evil)
     (if (package-installed-p package)
         nil
       (if (y-or-n-p (format "Package %s is missing. Install it? " package))
           (package-install package)
         package)))
   packages))

;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
    (package-refresh-contents))

(ensure-package-installed 'iedit 'magit) ;  --> (nil nil) if iedit and magit are already installed

;; activate installed packages
(package-initialize)

Emacs 25.1+ verfolgt automatisch die vom Benutzer installierten Pakete in der anpassbaren package-selected-packagesVariablen. package-installaktualisiert die Anpassungsvariable und Sie können alle ausgewählten Pakete mit der package-install-selected-packagesFunktion installieren .

Ein weiterer praktischer Vorteil dieses Ansatzes besteht darin, dass Sie package-autoremovePakete, die nicht in enthalten sind, automatisch entfernen können package-selected-packages(obwohl Abhängigkeiten erhalten bleiben).

(package-initialize)
(unless package-archive-contents
  (package-refresh-contents))
(package-install-selected-packages)

Quelle: http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html

Hier ist der Code, den ich für Emacs Prelude verwende :

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

Wenn Sie MELPA nicht verwenden, müssen Sie es nicht benötigen (und wenn Sie dies tun, müssen Sie melpa.eles auf Ihrem load-pathComputer haben (oder über MELPA installiert haben). Das Paket db wird nicht jedes Mal aktualisiert (da dies den Start erheblich verlangsamen würde ) - nur wenn deinstallierte Pakete vorhanden sind.

Noch hat niemand Cask erwähnt , aber es ist für diese Aufgabe durchaus geeignet.

Grundsätzlich erstellen Sie eine ~/.emacs.d/CaskListe der Pakete, die Sie installieren möchten. Beispielsweise:

(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc

Wenn Sie casküber die Befehlszeile ausgeführt werden, werden diese Pakete und alle erforderlichen Abhängigkeiten für Sie installiert.

Sie können installierte Pakete auch automatisch mit aktualisieren cask update.

Rufen Sie package-installmit dem Paketnamen als Symbol auf. Sie können die Paketnamen für Ihre Pakete finden, indem Sie package-installinteraktiv aufrufen und den Namen eingeben. Die Funktion package-installed-pinformiert Sie, wenn sie bereits installiert wurde.

Beispielsweise:

(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))

(require 'cl)
(require 'package)

(setq cfg-var:packages '(
       emmet-mode
       ergoemacs-mode
       flycheck
       flycheck-pyflakes
       monokai-theme
       py-autopep8
       py-isort
       rainbow-mode
       yafolding
       yasnippet))

(defun cfg:install-packages ()
    (let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
        (when pkgs
            (message "%s" "Emacs refresh packages database...")
            (package-refresh-contents)
            (message "%s" " done.")
            (dolist (p cfg-var:packages)
                (package-install p)))))

(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)

(cfg:install-packages)

Ich überprüfe gerne, ob der Benutzer die Pakete zuerst installieren möchte, wie in dieser Antwort beschrieben . Außerdem aktualisiere ich meinen Paketinhalt einmal, bevor ich etwas installiere. Ich bin mir nicht sicher, ob dies der beste Weg ist, aber ich glaube nicht, dass die besten Antworten dies für mich getan haben.

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

Ich lief in ein Problem , dass nichts passiert nach dem Hinzufügen (package-install 'org)in .emacs. Ich wollte die aktuelle Version von installieren org-modeund die eingebaute org-modeist ziemlich alt.

Ich habe den Quellcode package-installvon Emacs 25.3.1 ausgegraben. Die Funktion selbst prüft bereits, ob ein Paket installiert ist oder nicht, und lehnt die Installation ab, wenn das Paket bereits installiert ist. Der Scheck (unless (package-installed-p package) ...)aus Antwort 10093312 ist also in der Tat unangebracht.

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

Das integrierte Gerät gilt org-modeauch als installiert und package-installweigert sich, die neuere Version von ELPA zu installieren. Nachdem ich einige Zeit damit verbracht hatte, package.el zu lesen, kam ich auf die folgende Lösung.

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

Der Grund, warum es funktioniert, ist, dass package-*Familienfunktionen die Argumente unterschiedlich behandeln, je nachdem, ob es sich um ein Symbol oder ein package-descObjekt handelt. Sie können Versionsinformationen nur package-installüber ein package-descObjekt angeben .

Hier ist meins, es ist kürzer :)

(mapc
 (lambda (package)
   (unless (package-installed-p package)
     (progn (message "installing %s" package)
            (package-refresh-contents)
            (package-install package))))
 '(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))

Hier ist ein anderer Weg.

;; assure every package is installed
(defun ensure-package-installed (&rest packages)
  (let ((user-required-packages
         (seq-remove
          (lambda (package) (package-installed-p package))
          packages)))
    (when user-required-packages
      (package-refresh-contents)
      (dolist (package user-required-packages)
        (package-install package)))))

;; list of packages to install
(ensure-package-installed
 'try
 'which-key)