Erstellen eines Dateinamens als Zeitstempel in einem Stapeljob

Wir haben einen Stapeljob, der jeden Tag ausgeführt wird und eine Datei in einen Abholordner kopiert. Ich möchte auch eine Kopie dieser Datei nehmen und sie in einem Archivordner mit dem Dateinamen ablegen

 yyyy-MM-dd.log

Was ist der einfachste Weg, dies in einem Windows-Stapeljob zu tun?

Ich suche im Grunde nach einem Äquivalent zu diesem Unix-Befehl:

cp source.log `date +%F`.log

CP source.log %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%.log

Aber es ist vom Gebietsschema abhängig. Ich bin nicht sicher, ob %DATE%es lokalisiert ist oder von dem Format abhängt, das für das kurze Datum in Windows angegeben wurde.

Hier ist eine vom Gebietsschema unabhängige Methode, um das aktuelle Datum aus dieser Antwort zu extrahieren. Dies hängt jedoch von WMICund ab FOR /F:

FOR /F %%A IN ('WMIC OS GET LocalDateTime ^| FINDSTR \.') DO @SET B=%%A
CP source.log %B:~0,4%-%B:~4,2%-%B:~6,2%.log

Dies funktionierte für mich und war eine dateinamensichere Lösung (obwohl sie ein MM-TT-JJJJ-Format generiert):

C:\ set SAVESTAMP=%DATE:/=-%@%TIME::=-%
C:\ set SAVESTAMP=%SAVESTAMP: =%
C:\ set SAVESTAMP=%SAVESTAMP:,=.%.jpg
C:\ echo %SAVESTAMP%
[email protected]

Der erste Befehl nimmt ein DATE und ersetzt /durch -, nimmt die TIME und ersetzt :durch -und kombiniert sie im DATE @ TIME-Format. Die zweite setAnweisung entfernt Leerzeichen und die dritte setersetzt die Erweiterung ,durch .und hängt sie an .jpg.

Der obige Code wird in einem kleinen Skript verwendet, das Bilder von einer IP-Sicherheitskamera zur weiteren Verarbeitung abruft:

:while
set SAVESTAMP=%DATE:/=-%@%TIME::=-%
set SAVESTAMP=%SAVESTAMP: =%
set SAVESTAMP=%SAVESTAMP:,=.%.jpg
wget-1.10.2.exe --tries=0 -O %SAVESTAMP% http://admin:<password>@<ip address>:<port>/snapshot.cgi
timeout 1
GOTO while

Seien Sie NUR für das französische Gebietsschema (Frankreich) vorsichtig, da es /im Datum angegeben ist:

echo %DATE%
08/09/2013

Für unser Problem mit der Protokolldatei ist hier NUR mein Vorschlag für das französische Gebietsschema :

SETLOCAL
set LOGFILE_DATE=%DATE:~6,4%.%DATE:~3,2%.%DATE:~0,2%
set LOGFILE_TIME=%TIME:~0,2%.%TIME:~3,2%
set LOGFILE=log-%LOGFILE_DATE%-%LOGFILE_TIME%.txt
rem log-2014.05.19-22.18.txt
command > %LOGFILE%

Hier ist eine vom Gebietsschema unabhängige Lösung (Kopie in eine Datei mit dem Namen SetDateTimeComponents.cmd):

@echo off
REM This script taken from the following URL:
REM http://www.winnetmag.com/windowsscripting/article/articleid/9177/windowsscripting_9177.html

REM Create the date and time elements.
for /f "tokens=1-7 delims=:/-, " %%i in ('echo exit^|cmd /q /k"prompt $d $t"') do (
   for /f "tokens=2-4 delims=/-,() skip=1" %%a in ('echo.^|date') do (
      set dow=%%i
      set %%a=%%j
      set %%b=%%k
      set %%c=%%l
      set hh=%%m
      set min=%%n
      set ss=%%o
   )
)

REM Let's see the result.
echo %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss%

Ich habe alle meine .cmd-Skripte in demselben Ordner abgelegt (% SCRIPTROOT%). Jedes Skript, das Datums- / Zeitwerte benötigt, ruft SetDateTimeComponents.cmd wie im folgenden Beispiel auf:

setlocal

@echo Initializing...
set SCRIPTROOT=%~dp0
set ERRLOG=C:\Oopsies.err

:: Log start time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : Start === >> %ERRLOG%

:: Perform some long running action and log errors to ERRLOG.

:: Log end time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : End === >> %ERRLOG%

Wie das Beispiel zeigt, können Sie SetDateTimeComponents.cmd jederzeit aufrufen, wenn Sie die Datums- / Zeitwerte aktualisieren müssen. Das Ausblenden des Zeitanalyse-Skripts in seiner eigenen SetDateTimeComponents.cmd-Datei ist eine gute Möglichkeit, die hässlichen Details auszublenden und vor allem Tippfehler zu vermeiden.

Da die Idee, sie auseinander zu reißen %DATE%und %TIME%auseinander zu zerdrücken, bestenfalls fragil erscheint, ist hier eine Alternative, die einen Powershell-Oneliner verwendet:

for /f %i in ('powershell -c "get-date -format yyyy-MM-dd--HH-mm-ss"') do @set DATETIME=%i
set LOGFILE=my-script-%DATETIME%.txt

Referenz für get-dateist hier , mit Formatoptionen sowohl für .NET-Stil und UNIX-Stil.

Ich benutze dies häufig und füge alles in einen einzigen Kopierbefehl ein. Im Folgenden wird example.txt als example_YYYYMMDD_HHMMSS.txt kopiert, und Sie können es natürlich an Ihr bevorzugtes Format anpassen. Die Anführungszeichen sind nur erforderlich, wenn in der Dateispezifikation Leerzeichen vorhanden sind. Wenn Sie genau das gleiche Datum / den gleichen Zeitstempel wiederverwenden möchten, müssen Sie ihn in einer Variablen speichern.

copy "{path}\example.txt" "{path}\_%date:~10,4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt"

Dadurch wird sichergestellt, dass die Ausgabe zweistellig ist. Sie können die Ausgabe nach Ihren Wünschen anordnen und testen, indem Sie den Kommentarbereich deaktivieren. Genießen!

(Ich habe viel davon aus anderen Foren ausgeliehen ...)

:: ------------------ Date and Time Modifier ------------------------

@echo off
setlocal

:: THIS CODE WILL DISPLAY A 2-DIGIT TIMESTAMP FOR USE IN APPENDING FILENAMES

:: CREATE VARIABLE %TIMESTAMP%

for /f "tokens=1-8 delims=.:/-, " %%i in ('echo exit^|cmd /q /k"prompt $D $T"') do (
   for /f "tokens=2-4 skip=1 delims=/-,()" %%a in ('echo.^|date') do (
set dow=%%i
set %%a=%%j
set %%b=%%k
set %%c=%%l
set hh=%%m
set min=%%n
set sec=%%o
set hsec=%%p
)
)

:: ensure that hour is always 2 digits

if %hh%==0 set hh=00
if %hh%==1 set hh=01
if %hh%==2 set hh=02
if %hh%==3 set hh=03
if %hh%==4 set hh=04
if %hh%==5 set hh=05
if %hh%==6 set hh=06
if %hh%==7 set hh=07
if %hh%==8 set hh=08
if %hh%==9 set hh=09


:: --------- TIME STAMP DIAGNOSTICS -------------------------

:: Un-comment these lines to test output

:: echo dayOfWeek = %dow%
:: echo year = %yy%
:: echo month = %mm%
:: echo day = %dd%
:: echo hour = %hh%
:: echo minute = %min%
:: echo second = %sec%
:: echo hundredthsSecond = %hsec%
:: echo.
:: echo Hello! 
:: echo Today is %dow%, %mm%/%dd%. 
:: echo.
:: echo. 
:: echo.
:: echo.
:: pause

:: --------- END TIME STAMP DIAGNOSTICS ----------------------

:: assign timeStamp:
:: Add the date and time parameters as necessary - " yy-mm-dd-dow-min-sec-hsec "

endlocal & set timeStamp=%yy%%mm%%dd%_%hh%-%min%-%sec%
echo %timeStamp%

Erstellen Sie eine Datei mit dem aktuellen Datum als Dateiname (z. B. 2008-11-08.dat).

echo hello > %date%.dat    

Mit dem aktuellen Datum aber ohne das "-" (ex. 20081108.dat)

echo hello > %date:-=%.dat   

Vielleicht kann das helfen:

echo off
@prompt set date=$d$_ set time=$t$h$h$h
echo some log >> %date% %time%.log
exit

oder

echo off
set v=%date%.log
echo some log >> %v%

Ich habe ein kleines C-Programm zusammengestellt, um den aktuellen Zeitstempel auszudrucken (länderspezifisch, keine schlechten Zeichen ...). Dann benutze ich den Befehl FOR, um das Ergebnis in einer Umgebungsvariablen zu speichern:

:: Get the timestamp
for /f %%x in ('@timestamp') do set TIMESTAMP=%%x

:: Use it to generate a filename
for /r %%x in (.\processed\*) do move "%%~x" ".\archived\%%~nx-%TIMESTAMP%%%~xx"

Hier ist ein Link:

https://github.com/HarryPehkonen/dos-timestamp

Ich weiß, dass dieser Thread alt ist, aber ich möchte ihn hier nur hinzufügen, weil er mir sehr geholfen hat, dies alles herauszufinden und es ist sauber. Das Schöne daran ist, dass Sie es in eine Schleife für eine Batch-Datei setzen können, die immer ausgeführt wird. Server-Betriebszeitprotokoll oder so. Dafür benutze ich es sowieso. Ich hoffe das hilft irgendwann jemandem.

@setlocal enableextensions enabledelayedexpansion
@echo off

call :timestamp freshtime freshdate
echo %freshdate% - %freshtime% - Some data >> "%freshdate - Somelog.log"

:timestamp
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
set FreshTime=%hour%:%min%:%secs%

set year=%date:~-4%
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~7,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
set FreshDate=%month%.%day%.%year%

Sie können einfach das aktuelle lokale Format erkennen und das Datum in Ihrem Format abrufen, zum Beispiel:

::for 30.10.2016 dd.MM.yyyy
if %date:~2,1%==. set d=%date:~-4%%date:~3,2%%date:~,2%
::for 10/30/2016 MM/dd/yyyy
if %date:~2,1%==/ set d=%date:~-4%%date:~,2%%date:~3,2%
::for 2016-10-30 yyyy-MM-dd
if %date:~4,1%==- set d=%date:~,4%%date:~5,2%%date:~-2%
::variable %d% have now value: 2016103 (yyyyMMdd)
set t=%time::=%
set t=%t:,=%
::variable %t% have now time without delimiters
cp source.log %d%_%t%.log

Ich weiß, dass dies ein alter Beitrag ist, aber es gibt eine weitaus einfachere Antwort (obwohl dies möglicherweise nur in neueren Windows-Versionen funktioniert). Verwenden Sie einfach den Parameter / t für die Dos-Befehle DATE und TIME, um nur das Datum oder die Uhrzeit anzuzeigen und Sie nicht dazu aufzufordern, es wie folgt einzustellen:

@echo off
echo Starting test batch file > testlog.txt
date /t >> testlog.txt
time /t >> testlog.txt

1) Sie können GNU- Coreutils herunterladen, die mit dem GNU-Datum geliefert werden

2) Sie können VBScript verwenden , was die Datumsmanipulation in Windows erleichtert:

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder = "c:\test"
Set objFolder = objFS.GetFolder(strFolder)
current = Now
mth = Month(current)
d = Day(current)
yr = Year(current)
If Len(mth) <2 Then
    mth="0"&mth
End If
If Len(d) < 2 Then
    d = "0"&d
End If
timestamp=yr & "-" & mth &"-"& d
For Each strFile In objFolder.Files
    strFileName = strFile.Name
    If InStr(strFileName,"file_name_here") > 0 Then
        BaseName = objFS.GetBaseName(strFileName)
        Extension = objFS.GetExtensionName(strFileName)
        NewName = BaseName & "-" & timestamp & "." & Extension
        strFile.Name = NewName
    End If
Next

Führen Sie das Skript wie folgt aus:

c:\test> cscript /nologo myscript.vbs

Dies funktioniert gut mit (meinem) deutschen Gebietsschema, sollte es möglich sein, es an Ihre Bedürfnisse anzupassen ...

forfiles /p *PATH* /m *filepattern* /c "cmd /c ren @file 
%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_@file"

Für große Zip-Dateien für die Bereitstellung verwende ich Viertelstunden. Niemand sonst auf dieser Seite hatte es zuvor erwähnt, daher werde ich mein kleines Skript hier einfügen:

set /a "quarter_hours=%time:~0,2%*4 + %time:~3,2% / 15"
set "zip_file=release_%DATE:~-4%.%DATE:~4,2%.%DATE:~7,2%.%quarter_hours%.zip"

Es ist noch keine Viertelstunde von Mitternacht bis 5 Uhr morgens, aber es macht es trotzdem so, dass Sie mehrmals am Tag eine gestempelte Veröffentlichung mit wenigen Kollisionen haben können.

Hoffentlich hilft das.

benutzte Martins Vorschlag mit einer kleinen Änderung, um dem Dateinamen einen Zeitstempel hinzuzufügen:

forfiles /p [foldername] /m rsync2.log /c "cmd /c ren @file %DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_%time:~-11,2%-%time:~-8,2%-%time:~-5,2%-@file

Für den 10:17:21 23/10/2019 Das Ergebnis ist:

20191023_10-17-21-rsync2.log