Lassen Sie Vim ALLE Leerzeichen als Charakter anzeigen

Ich kann keinen Weg finden, Vim dazu zu bringen, alle Leerzeichen als Charakter anzuzeigen. Ich fand nur Tabulatoren, Leerzeichen usw.

Wie andere gesagt haben, könnten Sie verwenden

:set list

was wird, in Kombination mit

:set listchars=...

unsichtbare Zeichen anzeigen.
Jetzt gibt es keine explizite Option , die Sie verwenden können , um zu zeigen , Leerzeichen, aber in listchars, könnten Sie einen Zeichensatz für alles ABER Leerzeichen zu zeigen. Zum Beispiel sieht meine so aus

:set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<

Also, jetzt, nachdem Sie verwendet haben

:set list

Alles, was nicht explizit als etwas anderes angezeigt wird, ist dann wirklich ein einfaches altes Leerzeichen.

listcharsVerwenden Sie wie gewohnt die Hilfe , um zu verstehen, wie dies funktioniert. Es bietet großartige Informationen darüber, welche Zeichen angezeigt werden können (z. B. nachfolgendes Leerzeichen) und wie dies zu tun ist:

:help listchars

Es kann hilfreich sein, einen Umschalter hinzuzufügen, damit Sie die Änderungen während der Bearbeitung leicht sehen können (Quelle: VIM: Set List! Als Umschalter in .vimrc ):

noremap <F5> :set list!<CR>
inoremap <F5> <C-o>:set list!<CR>
cnoremap <F5> <C-c>:set list!<CR>

Ab Patch 7.4.710 können Sie jetzt mithilfe von Listchars ein Zeichen festlegen, das anstelle des Leerzeichens angezeigt wird!

:set listchars+=space:␣

Um ALLE Leerzeichen als Zeichen anzuzeigen, haben Sie folgende Möglichkeiten:

:set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
:set list

Diskussion zur Mailingliste: https://groups.google.com/forum/?fromgroups#!topic/vim_dev/pjmW6wOZW_Q

:set list ermöglichen.

:set nolist Etwas deaktivieren.

Ich denke, andere Antworten hier sind umfassender, aber ich dachte, ich würde einen Trick teilen, den ich normalerweise verwende, um Tabulatoren und Leerzeichen visuell zu unterscheiden:

:syntax on
:set syntax=whitespace

Hierbei handelt es sich um Syntaxhervorhebungsregeln für die Programmiersprache Whitespace. Registerkarten werden in Grün und Leerzeichen in Rot angezeigt . :) :)

Kann :set listwie von vielen anderen Antworten erwähnt kombiniert werden , obwohl die Registerkarten dann als ^ I ohne grünes Higlight angezeigt werden, die Leerzeichen jedoch rot angezeigt werden.

:set listzeigt alle Leerzeichen als Zeichen an. Alles außer einem Raum sieht anders aus als sein normaler Zustand, was bedeutet, dass wenn Sie immer noch einen einfachen alten Raum sehen, es wirklich ein einfacher alter Raum ist. :) :)

Wenn Sie einstellen:

:highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none

Wenn Sie dann nach einem Leerzeichen suchen, wird jedes Leerzeichen als Unterstreichungszeichen angezeigt.

Sie können diesen Befehl in einer praktischen Funktion verwenden, mit der das "Unterstreichen" von Leerzeichen umgeschaltet wird.

set hls
let g:HLSpace = 1
let g:HLColorScheme = g:colors_name
function ToggleSpaceUnderscoring()
    if g:HLSpace
        highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none
        let @/ = " "
    else
        highlight clear
        silent colorscheme "".g:HLColorScheme
        let @/ = ""
    endif
    let g:HLSpace = !g:HLSpace
endfunction

Ordnen Sie die Funktion einer Tastenkombination zu:

nmap <silent> <F3> <Esc>:call ToggleSpaceUnderscoring()<CR>

NB: Definieren Sie die Funktion in vimrc, nachdem das Farbschema festgelegt wurde.

Abhängig von Ihren Syntaxregeln für den aktuellen Puffer könnte Folgendes funktionieren:

:syn match WhiteSpace / / containedin=ALL conceal cchar=Æ
:setl conceallevel=2 concealcursor=nv

Dies erfordert eine Version 7.3 mit + Verdeckungsfunktion

Update 24.10.2014 Um das ein wenig zu erweitern. Es ist natürlich möglich, einige Hervorhebungen für die verborgenen Zeichen zu definieren.

• Sie können konfigurieren, wie die verborgenen Zeichen aussehen. Zum Hervorheben müssten Sie mindestens einmal die Hervorhebungsgruppe "Verbergen" konfigurieren (siehe Hilfe unter :h hl-ConcealDies kann in Ihrem Farbschema erfolgen, und Sie müssen es dann nicht erneut konfigurieren. Dies betrifft jedoch alle verborgenen Zeichen (z. B. wenn Ihre Das Syntax-Skript verbirgt einige weitere Elemente. Sie werden als Leerzeichen angezeigt. Das könnte folgendermaßen aussehen:

  :hi Conceal ctermfg=7 ctermbg=NONE guifg=LightGrey guibg=NONE

• Es scheint eine Besonderheit zu geben, dass Vim keine Leerzeichen hervorhebt, wenn das Syntaxskript das skipwhiteSchlüsselwort verwendet. Es wird keinen Weg vorbei geben (vielleicht wird dies behoben, ich habe einen Patch gepostet )

• Es scheint einen Patch zu geben, mit dem Sie anpassen können, wie Leerzeichen im listModus aussehen . Der letzte zum Zeitpunkt des Schreibens scheint dieser zu sein . (Dies bedeutet, dass Sie Ihr eigenes Vim erstellen müssen, um dies zu verwenden).
• Die conceallevelund concealcursorsind fensterlokale Optionen. Das bedeutet, dass sie in verschiedenen Fenstern unterschiedlich sein können (und möglicherweise auch durch Dateityp-Plugins oder andere Plugin-Skripte festgelegt werden).
• Die Syntaxhervorhebungsgruppen müssen immer dann ausgeführt werden, wenn eine Syntaxdefinitionsdatei neu geladen wird. Dies könnte mit einem BufWinEnteroder möglicherweise auch einem Syntaxoder sogar einem FileTypeAutobefehl erfolgen. (Ich habe nicht getestet, welches tatsächlich funktioniert).

Die letzten beiden Elemente bedeuten, dass Sie einige automatische Befehle einrichten müssen, die die Syntaxregeln und die entsprechenden Optionen zurücksetzen. Für den ersten Fall möchten Sie möglicherweise die Hervorhebung mithilfe eines ColorSchemeautomatischen Befehls einrichten (damit die verborgenen Zeichen immer gleich aussehen, unabhängig davon, was ein Farbschema tatsächlich einrichtet). Eine vollständige Lösung finden Sie in der Antwort von romainl, die Ihnen einen Anfang geben sollte. Wenn Sie eine Funktion einrichten, können Sie einfach einen Umschaltbefehl einrichten, um die Anzeige der speziellen Hervorhebung ein- oder auszuschalten.

Update 26.10.2014 Ich habe aus dieser Frage ein Plugin gemacht .

Update 22.04.2015 In Vim wurde ein Patch aufgenommen, der dies mithilfe der listOption ermöglicht. Einfach einstellen set list listchars+=space:␣ Dies funktioniert ab Vim 7.4.711

ich benutze das

/\s
:set hlsearch

um Leerzeichen hervorzuheben. Es sucht nach allen Leerzeichen und aktiviert dann die Hervorhebung, damit sie herausspringen. Es wird jedoch kein Sonderzeichen gedruckt.

Wenn Sie mit Leerzeichen das Zeichen '' meinen, wäre mein Vorschlag nur ein Suchen / Ersetzen. Wie die anderen angedeutet haben, set listwerden nicht druckbare Zeichen in sichtbare Zeichen geändert , die in konfiguriert sind listchars.

Um Leerzeichen explizit als ein anderes Zeichen anzuzeigen, sollte etwas Ähnliches wie das Folgende den Trick tun:

:%s/ /█/g

Machen Sie dann einfach die Änderung rückgängig, um wieder zurückzukehren.

(um die █ ich genau diese Tastenfolge gedrückt: :%s/ /CTRL-KFB/g)

Um Leerzeichen hervorzuheben, suchen Sie einfach danach:

/ <Leerzeichen>

Anmerkungen:

Der folgende Code basiert auf der Antwort von Christian Brabandt und scheint zu tun, was das OP will:

function! Whitespace()
    if !exists('b:ws')
        highlight Conceal ctermbg=NONE ctermfg=240 cterm=NONE guibg=NONE guifg=#585858 gui=NONE
        highlight link Whitespace Conceal
        let b:ws = 1
    endif

    syntax clear Whitespace
    syntax match Whitespace / / containedin=ALL conceal cchar=·
    setlocal conceallevel=2 concealcursor=c
endfunction

augroup Whitespace
    autocmd!
    autocmd BufEnter,WinEnter * call Whitespace()
augroup END

Fügen Sie diese Zeilen an Ihre hinzu ~/.vimrcund starten Sie eine neue Vim-Sitzung, um zu sehen, wie die immer noch unvollkommene Magie geschieht.

Fühlen Sie sich frei, die Standardfarben zu bearbeiten und Zeichen zu verbergen.

Vorsichtsmaßnahme: Etwas in der *FuncBodySyntaxgruppe in mehreren Sprachen verhindert, dass der mittlere Punkt angezeigt wird. Ich weiß (noch?) Nicht, wie ich diese Lösung zuverlässiger machen kann.

Ich war mit all den anderen Antworten auf diese Frage frustriert, weil keine von ihnen den Raumcharakter auf nützliche Weise hervorhebt. Das Anzeigen von Leerzeichen als Zeichen ist besonders hilfreich für Sprachen im Leerzeichenformat, bei denen das Mischen von Tabulatoren und Leerzeichen schädlich ist.

Meine Lösung besteht darin, Tabulatoren anzuzeigen und mehrere Leerzeichen zu unterstreichen. Es leiht sich aus Mruccis Antwort und diesem Tutorial . Da die Syntaxhervorhebung verwendet wird, ist sie dauerhaft:

set list listchars=tab:\|\ 
highlight Whitespace cterm=underline gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
autocmd ColorScheme * highlight Whitespace gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
match Whitespace /  \+/

Auf diese Weise werden Registerkarten als |und Leerzeichen als angezeigt _, wodurch es sehr einfach ist zu erkennen, wann ich Codestile mische.

Der einzige Nachteil, den ich festgestellt habe, ist, dass dieses Snippet die Hintergrundfarbe nicht an den Kontext anpasst (wie in einem Kommentar).

Alle obigen Antworten versuchen, Leerzeichen von vim aus sichtbar zu machen. Wenn Sie wirklich darauf bestehen, sichtbare Räume als Punkte zu haben, gibt es einen anderen Ansatz ...

Wenn dies in vim nicht möglich ist, ändern Sie Ihre Schriftart vollständig. Ich habe die Ubuntu One Mono-Schriftart kopiert und mit FontForge bearbeitet. Denken Sie daran, den vollständigen Namen, die Familie, die bevorzugte Familie und die kompatible Vollschrift der Schriftart zu ändern (in FontFoge unter TTF-Namen in den Schriftartinformationen), um sie als separate Schriftart zu verwenden. Bearbeiten Sie einfach das Leerzeichen, um einen Punkt in der Mitte zu haben, und speichern Sie die Schriftart in ~ / .fonts. Jetzt können Sie sie für Ihr GVIM oder das gesamte Terminal verwenden ... Ich habe das "!" Zeichen, entfernte die Linie und verschob den Punkt in die Mitte. Es dauerte etwas mehr als 5 Minuten ...

Hinweis: Das Ändern des Leerzeichens (0x20) führt zu der Unannehmlichkeit, Punkte auf dem gesamten VIM-Bildschirm zu haben ... (aber es werden die Leerzeichen von den Tabulatoren getrennt ...)

Ich habe aus den vorhandenen Antworten nicht genau das gefunden, was ich wollte. Der folgende Code hebt alle nachfolgenden Leerzeichen hellrot hervor. Fügen Sie einfach Folgendes zu Ihrem hinzu.vimrc

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

:match CursorLine /\s\+/

Vermeidet das Bit "Sie müssen nach Leerzeichen suchen, damit sie angezeigt werden", aber afaict kann nicht so konfiguriert werden, dass die Leerzeichen nicht hügelig sind. CursorLine kann eine beliebige Hilighting-Gruppe sein und ist im Standarddesign eine einfache Unterstreichung.

Ich mag es, Sonderzeichen zu verwenden, um Leerzeichen anzuzeigen, ist klarer. Sogar eine Karte zum Umschalten ist eine wichtige Funktion für eine schnelle Überprüfung.

Sie finden diese Funktionen in einem alten vim-Skript, das seit 2004 nicht mehr aktualisiert wurde:

vim-scripts/[email protected]

Dank Projekt- Vim-Skripten und Vundle können Sie dieses Plugin wieder zum Leben erwecken

vim-scripts / cream-showinvisibles @ github

Noch besser ist, dass meine zwei Cent darin bestehen, eine konfigurierbare Verknüpfung hinzuzufügen (anstatt vordefiniert F4)

Fügen Sie dies also zu ~ / .vimrc hinzu

Plugin 'albfan/cream-invisibles'

let g:creamInvisibleShortCut = "<F5>" "for my F4 goto next error

Installieren Sie das Plugin auf vim

:PluginInstall

und los geht's

So decken Sie Unicode-Leerzeichen ab:

set list
set listchars=tab:│\ ,nbsp:·
highlight StrangeWhitespace guibg=Red ctermbg=Red
" The list is from https://stackoverflow.com/a/37903645 (with `\t`, `\n`, ` `, `\xa0` removed):
call matchadd('StrangeWhitespace', '[\x0b\x0c\r\x1c\x1d\x1e\x1f\x85\u1680\u2000\u2001\u2002\u2003\u2004\u2005\u2006\u2007\u2008\u2009\u200a\u2028\u2029\u202f\u205f\u3000]')

Das Ergebnis:

• nur der Ordnungsraum (U + 0020) sieht genauso aus wie ein Leerzeichen (" ")
• Die Registerkarte (U + 0009) sieht aus wie " │ " (zwei Zeichen: eine lange Pipe und dann ein Ordnungsraum; sie sind grau colorscheme murphy)
• Das normale Leerzeichen (U + 00A0) sieht aus wie " ·" (ein Zeichen; es ist grau in colorscheme murphy)
• jedes andere Leerzeichen sieht aus wie rot " "

Du könntest benutzen

:set list

um die Struktur einer Linie wirklich zu sehen. Sie sehen explizit Registerkarten und Zeilenumbrüche. Wenn Sie ein Leerzeichen sehen, ist es wirklich ein Leerzeichen.

Suche markieren

:set hlsearch 

in .vimrcdem ist

und suchen Sie nach Leerzeichen und Wagenrückläufen

/ \|\t\|\r

oder suchen Sie nach allen Leerzeichen

/\s

der Suche nach allen Nicht-Leerzeichen (die Leerzeichen werden nicht angezeigt, sodass Sie die Leerzeichen zwischen den Wörtern sehen, nicht jedoch die nachfolgenden Leerzeichen).

/\S

um alle nachfolgenden Leerzeichen anzuzeigen - am Ende der Zeile

/\s$

Behalten Sie diese Hacks in der .vimrc als Kommentare, also in der Shell einfach:

echo '
  " how-to see the non-visible while spaces
  " :set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
  " set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<
  " :set list
  " but hei how-to unset the visible tabs ?!
  " :set nolist
  ' >> ~/.vimrc

:se list
:se nolist

:seist genug, :setwird nicht benötigt.

Sie können auch die Leerzeichen markieren (die Leerzeichen durch einen Block ersetzen):

:%s/ /█/g

(vor dem Schreiben rückgängig machen)

Das Hinzufügen zu meiner .vimrc funktioniert für mich. Stellen Sie nur sicher, dass nichts anderes in Konflikt steht.

autocmd VimEnter * :syn match space /\s/
autocmd VimEnter * :hi space ctermbg=lightgray ctermfg=black guibg=lightgray guifg=black