Wie stelle ich die Warnstufe in CMake ein?

Wie kann ich mit CMake die Warnstufe für ein Projekt (nicht die gesamte Lösung) festlegen ? Sollte unter Visual Studio und GCC funktionieren .

Ich habe verschiedene Optionen gefunden, aber die meisten scheinen entweder nicht zu funktionieren oder stimmen nicht mit der Dokumentation überein.

UPDATE: Diese Antwort stammt aus der Zeit vor dem Modern CMake. Jeder vernünftige CMake-Benutzer sollte nicht CMAKE_CXX_FLAGSdirekt herumspielen und target_compile_optionsstattdessen den Befehl aufrufen . Überprüfen Sie die Antwort des mrts, die die empfohlenen Best Practices enthält.

Sie können etwas Ähnliches tun:

if(MSVC)
  # Force to always compile with W4
  if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
    string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  else()
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
  endif()
elseif(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  # Update if necessary
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wno-long-long -pedantic")
endif()

Im modernen CMake funktioniert Folgendes gut:

if(MSVC)
  target_compile_options(${TARGET_NAME} PRIVATE /W4 /WX)
else()
  target_compile_options(${TARGET_NAME} PRIVATE -Wall -Wextra -pedantic -Werror)
endif()

Mein Kollege schlug eine alternative Version vor:

target_compile_options(${TARGET_NAME} PRIVATE
  $<$<CXX_COMPILER_ID:MSVC>:/W4 /WX>
  $<$<NOT:$<CXX_COMPILER_ID:MSVC>>:-Wall -Wextra -pedantic -Werror>
)

Durch ${TARGET_NAME}den tatsächlichen Zielnamen ersetzen . -Werrorist optional, verwandelt alle Warnungen in Fehler.

Oder verwenden add_compile_options(...)Sie, wenn Sie es auf alle Ziele anwenden möchten, wie von @aldo in den Kommentaren vorgeschlagen.

Stellen Sie außerdem sicher, dass Sie den Unterschied zwischen PRIVATEund verstehen PUBLIC(öffentliche Optionen werden von Zielen geerbt, die vom angegebenen Ziel abhängen).

Einige CMake-Module, die ich geschrieben habe, enthalten experimentelle plattformübergreifende Warnunterdrückung :

sugar_generate_warning_flags(
    target_compile_options
    target_properties
    ENABLE conversion
    TREAT_AS_ERRORS ALL
)

set_target_properties(
    foo
    PROPERTIES
    ${target_properties}
    COMPILE_OPTIONS
    "${target_compile_options}"
)

Ergebnis für Xcode:

• Legen Sie das CLANG_WARN_SUSPICIOUS_IMPLICIT_CONVERSIONXcode-Attribut fest (auch bekannt als Build-Einstellungen -> Warnungen -> verdächtige implizite Konvertierungen -> JA )
• Compiler-Flag hinzufügen: -Werror

Makefile gcc und clang:

• In Compiler - Flags: -Wconversion,-Werror

Visual Studio:

• In Compiler - Flags: /WX,/w14244

Links

• Liste der verfügbaren Warnungen
• Verwendung und weitere Optionen

Hier ist die beste Lösung, die ich bisher gefunden habe (einschließlich einer Compilerprüfung):

if(CMAKE_BUILD_TOOL MATCHES "(msdev|devenv|nmake)")
    add_definitions(/W2)
endif()

Dadurch wird die Warnstufe 2 in Visual Studio festgelegt. Ich nehme an mit einem-W2 würde es auch in GCC funktionieren (ungetestet).

Update von @Williams: Es sollte -Wallfür GCC sein.

Wie pro Cmake 3.17.1 Dokumentation :

if (MSVC)
    # warning level 4 and all warnings as errors
    add_compile_options(/W4 /WX)
else()
    # lots of warnings and all warnings as errors
    add_compile_options(-Wall -Wextra -pedantic -Werror)
endif()

GCC und Clang teilen sich diese Flags, daher sollte dies alle 3 abdecken.

if(MSVC)
    string(REGEX REPLACE "/W[1-3]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
endif()

Wenn Sie target_compile_options- cmake verwenden, wird versucht, das Doppelflag zu /W*verwenden, das vom Compiler gewarnt wird.