Wie finde ich heraus, wo JDK auf meinem Windows-Computer installiert ist?

Ich muss wissen, wo sich JDK auf meinem Computer befindet.

Beim Ausführen Java -versionin cmd wird die Version als '1.6.xx' angezeigt. Um den Speicherort dieses SDK auf meinem Computer zu ermitteln, habe ich versucht echo %JAVA_HOME%, es zu verwenden, aber es zeigt nur 'JAVA_HOME' an (da in meinen Umgebungsvariablen keine 'JAVA_PATH'-Variable festgelegt ist).

Wenn Sie Linux / Unix / Mac OS X verwenden:

Versuche dies:

$ which java

Sollte den genauen Ort ausgeben.

Danach können Sie die JAVA_HOMEUmgebungsvariable selbst festlegen .

Auf meinem Computer (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

Wenn Sie Windows verwenden:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i

Windows> Start> cmd>

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

Wenn Sie ein JDK installiert haben, wird der Pfad angezeigt,
zum Beispiel:C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

In Windows an der Eingabeaufforderung

where javac

In Windows lautet die Standardeinstellung: C:\Program Files\Java\jdk1.6.0_14(wobei sich die Zahlen unterscheiden können, da es sich um die Version handelt).

Das Java-Installationsprogramm legt mehrere Dateien im Ordner% WinDir% \ System32 ab (java.exe, javaws.exe und einige andere). Wenn Sie java.exe in die Befehlszeile eingeben oder einen Prozess ohne vollständigen Pfad erstellen, führt Windows diese als letzten Ausweg aus, wenn sie in% PATH% -Ordnern fehlen.

Sie können alle in der Registrierung installierten Java-Versionen nachschlagen. Schauen Sie sich HKLM \ SOFTWARE \ JavaSoft \ Java Runtime Environment und HKLM \ SOFTWARE \ Wow6432Node \ JavaSoft \ Java Runtime Environment für 32-Bit-Java unter 64-Bit-Windows an.

Auf diese Weise findet Java selbst heraus, dass verschiedene Versionen installiert sind. Aus diesem Grund können sowohl die 32-Bit- als auch die 64-Bit-Version nebeneinander existieren und funktionieren einwandfrei.

Schlicht und einfach auf Windows-Plattformen:

wo Java

Das folgende Batch-Skript druckt die vorhandene Standard-JRE aus. Es kann leicht geändert werden, um die installierte JDK-Version zu finden, indem die Java-Laufzeitumgebung durch das Java Development Kit ersetzt wird .

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal

Unter Windows 10 können Sie den Pfad unter Systemsteuerung> Java ermitteln. In dem angezeigten Bereich finden Sie den Pfad, wie im folgenden Screenshot gezeigt. Wechseln Sie in der Java-Systemsteuerung zur Registerkarte "Java" und klicken Sie auf die Schaltfläche "Ansicht" unter der Beschreibung "Anzeigen und Verwalten von Java Runtime-Versionen und -Einstellungen für Java-Anwendungen und -Applets".

Dies sollte unter Windows 7 und möglicherweise anderen neueren Windows-Versionen funktionieren.

Geben Sie an einer Windows-Eingabeaufforderung einfach Folgendes ein:

set java_home

Wenn Ihnen die Befehlsumgebung nicht gefällt, können Sie sie folgendermaßen überprüfen:

Startmenü> Computer> Systemeigenschaften> Erweiterte Systemeigenschaften. Öffnen Sie dann die Registerkarte Erweitert> Umgebungsvariablen und versuchen Sie in der Systemvariablen, JAVA_HOME zu finden.

Unter Windows können Sie verwenden

C:>dir /b /s java.exe

um den vollständigen Pfad jeder "java.exe" auf Ihrem Laufwerk C: zu drucken, unabhängig davon, ob sie sich in Ihrer Umgebungsvariablen PATH befinden.

Mehr unter Windows ... Die Variable java.home ist nicht immer derselbe Speicherort wie die ausgeführte Binärdatei.

Wie Denis The Menace sagt, fügt das Installationsprogramm Java-Dateien in Programmdateien , aber auch java.exe in System32 ein . Ohne Java auf dem Pfad kann Java-Version immer noch funktionieren. Wenn das Programm von PeterMmm ausgeführt wird, meldet es jedoch den Wert der Programmdateien als java.home . Dies ist nicht falsch (Java ist dort installiert), aber die tatsächlich ausgeführte Binärdatei befindet sich in System32 .

Um den Speicherort der Binärdatei java.exe zu ermitteln , fügen Sie dem Code von PeterMmm die folgende Zeile hinzu, damit das Programm noch eine Weile läuft:

try{Thread.sleep(60000);}catch(Exception e) {}

Kompilieren und führen Sie es aus und suchen Sie dann den Speicherort des Bildes java.exe . Öffnen Sie beispielsweise in Windows 7 den Task-Manager, suchen Sie den Eintrag java.exe , klicken Sie mit der rechten Maustaste und wählen Sie "Dateispeicherort öffnen". Dadurch wird der genaue Speicherort der Java-Binärdatei geöffnet. In diesem Fall wäre es System32 .

Führen Sie dieses Programm über die Befehlszeile aus:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main

Powershell One Liner:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome

Haben Sie versucht, Ihre Variable% PATH% zu betrachten? Das ist es, was Windows verwendet, um eine ausführbare Datei zu finden.

Führen Sie einfach die aus set Befehl in Ihrer Befehlszeile aus. Dann sehen Sie alle Umgebungsvariablen, die Sie festgelegt haben.

Oder wenn Sie es unter Unix vereinfachen können:

$ set | grep "JAVA_HOME" 

Dies ist betriebssystemspezifisch. Unter Unix:

which java

zeigt den Pfad zur ausführbaren Datei an. Ich kenne kein Windows-Äquivalent, aber dort befindet sich normalerweise der binOrdner der JDK-Installation im System PATH:

echo %PATH%

Keine dieser Antworten ist für Linux korrekt, wenn Sie nach einem Home suchen, das die Unterverzeichnisse enthält: bin, docs, include, jre, lib usw.

Unter Ubuntu für openjdk1.8.0 ist dies in: /usr/lib/jvm/java-1.8.0-openjdk-amd64

und Sie können es vorziehen, dies zu verwenden, JAVA_HOMEda Sie Header finden können, wenn Sie JNI-Quelldateien erstellen. Während es wahr ist, which javawird es den binären Pfad bereitstellen, aber es ist nicht das wahre JDK-Zuhause.

Führen Sie unter macOS Folgendes aus:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

Auf meinem Computer wird Folgendes gedruckt:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

Beachten Sie, dass beim Ausführen which javader JDK-Speicherort nicht angezeigt wird, da der javaBefehl stattdessen Teil von ist JavaVM.framework, der das echte JDK umschließt:

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

in Windows cmd:

set "JAVA_HOME" 

#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

Für Windows:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

Dieser Link kann hilfreich sein, um zu erklären, wie Sie eine ausführbare Java-Datei von bash finden: http://srcode.org/2014/05/07/detect-java-executable/

Ich habe die Antwort von munsingh oben verbessert, indem ich bei Bedarf in 64-Bit- und 32-Bit-Registern nach dem Registrierungsschlüssel getestet habe:

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

Referenz für den Zugriff auf die 64-Bit-Registrierung

Skript für 32/64 Bit Windows.

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal