Seit der Installation des Windows-Updates für Office 2010 zum Auflösen von KB 4484127 wird beim Ausführen von Abfragen, die eine WHERE-Klausel enthalten, eine Fehlermeldung angezeigt .

Beispiel: Ausführen dieser Abfrage:

DoCmd.RunSQL "update users set uname= 'bob' where usercode=1"

Ergebnisse in diesem Fehler:

Fehlernummer = 3340 Abfrage '' ist beschädigt

Das betreffende Update ist derzeit noch installiert:

Wie kann ich meine Abfragen erfolgreich ausführen? Sollte ich dieses Update einfach deinstallieren?

Zusammenfassung

Dies ist ein bekannter Fehler , der durch die am 12. November 2019 veröffentlichten Office-Updates verursacht wurde. Der Fehler betrifft alle Versionen von Access, die derzeit von Microsoft unterstützt werden (von Access 2010 bis 365).

Dieser Fehler wurde behoben.

• Wenn Sie eine C2R-Version (Click-to-Run) von Office verwenden, verwenden Sie "Jetzt aktualisieren " :
  • Access 2010 C2R: In Build 7243.5000 behoben
  • Access 2013 C2R: In Build 5197.1000 behoben
  • Access 2016 C2R: In Build 12130.20390 behoben
  • Zugriff 2019 (v1910): In Build 12130.20390 behoben
  • Zugriff 2019 (Volumenlizenz): In Build 10353.20037 behoben
  • Office 365-Monatskanal: In Build 12130.20390 behoben
  • Office 365 halbjährlich: In Build 11328.20480 behoben
  • Office 365 Semi-Annual Extended: In Build 10730.20422 behoben
  • Office 365 Semi-Annual Targeted: In Build 11929.20494 behoben
• Wenn Sie eine MSI-Version von Office verwenden, installieren Sie das Update, das Ihrer Office-Version entspricht. Alle diese Patches wurden in Microsoft Update veröffentlicht. Daher sollte die Installation aller ausstehenden Windows-Updates ausreichen:
  • Access 2010 MSI: In KB4484193 behoben
  • Access 2013 MSI: In KB4484186 behoben
  • Access 2016 MSI: In KB4484180 behoben

Beispiel

Hier ist ein minimales Repro-Beispiel:

1. Erstellen Sie eine neue Access-Datenbank.
2. Erstellen Sie eine neue, leere Tabelle "Table1" mit dem Standard-ID-Feld und einem Long Integer-Feld "myint".

3. Führen Sie den folgenden Code im Direktfenster des VBA-Editors aus:

   CurrentDb.Execute "UPDATE Table1 SET myint = 1 WHERE myint = 1"

Erwartetes Ergebnis : Die Anweisung wird erfolgreich beendet.

Tatsächliches Ergebnis mit einem der installierten fehlerhaften Updates: Laufzeitfehler 3340 tritt auf ("Abfrage '' ist beschädigt").

Verwandte Links:

• MSDN-Forenthread
• Offizielle Microsoft-Seite für diesen Fehler

Einfachste Lösung

Für meine Benutzer ist es keine Option, fast einen Monat bis zum 10. Dezember auf eine feste Version von Microsoft zu warten. Die Deinstallation des fehlerhaften Microsoft-Updates auf mehreren von der Regierung gesperrten Workstations ist ebenfalls nicht möglich.

Ich muss eine Problemumgehung anwenden, bin aber nicht gerade begeistert von den Vorschlägen von Microsoft - dem Erstellen und Ersetzen einer Abfrage für jede Tabelle.

Die Lösung besteht darin, den Tabellennamen durch einen einfachen zu ersetzen (SELECT * FROM Table) Abfrage direkt im UPDATEBefehl . Dies erfordert nicht das Erstellen und Speichern einer Menge zusätzlicher Abfragen, Tabellen oder Funktionen.

BEISPIEL:

Vor:

UPDATE Table1 SET Field1 = "x" WHERE (Field2=1);  

Nach:

UPDATE (SELECT * FROM Table1) SET Field1 = "x" WHERE (Field2=1);  

Dies sollte in mehreren Datenbanken und Anwendungen (und späterem Rollback) viel einfacher zu implementieren sein.

Dies ist kein Windows-Update-Problem, sondern ein Problem, das mit der Veröffentlichung des November Patch Tuesday Office eingeführt wurde. Eine Änderung zur Behebung einer Sicherheitslücke führt dazu, dass einige legitime Abfragen als beschädigt gemeldet werden. Da es sich bei der Änderung um eine Sicherheitskorrektur handelt, wirkt sie sich auf ALLE Office-Builds aus, einschließlich 2010, 2013, 2016, 2019 und O365.

Der Fehler wurde in allen Kanälen behoben, aber der Zeitpunkt der Lieferung hängt davon ab, auf welchem ​​Kanal Sie sich befinden.

Für die MSI- und 2019-Volumenlizenz-Builds 2010, 2013 und 2016 sowie den halbjährlichen O365-Kanal wird der Fix im Dezember-Patch-Dienstag-Build vom 10. Dezember enthalten sein. Für O365, Monthly Channel und Insider wird dies behoben Wenn die Oktobergabel freigegeben wird, ist dies derzeit für den 24. November geplant.

Für den halbjährlichen Kanal wurde der Fehler in 11328.20468 eingeführt, der am 12. November veröffentlicht wurde, aber nicht für alle auf einmal verfügbar ist. Wenn Sie können, möchten Sie die Aktualisierung möglicherweise bis zum 10. Dezember verschieben.

Das Problem tritt bei Aktualisierungsabfragen für eine einzelne Tabelle mit festgelegten Kriterien auf (daher sollten andere Abfragetypen nicht betroffen sein, keine Abfrage, die alle Zeilen einer Tabelle aktualisiert, oder eine Abfrage, die die Ergebnismenge einer anderen Abfrage aktualisiert). Angesichts dessen besteht die einfachste Problemumgehung in den meisten Fällen darin, die Aktualisierungsabfrage so zu ändern, dass eine andere Abfrage aktualisiert wird, die alles aus der Tabelle auswählt, anstatt die Abfrage direkt zu aktualisieren.

Dh wenn Sie eine Frage haben wie:

UPDATE Table1 SET Table1.Field1 = "x" WHERE ([Table1].[Field2]=1);

Erstellen Sie dann eine neue Abfrage (Query1), die wie folgt definiert ist:

Select * from Table1;

und aktualisieren Sie Ihre ursprüngliche Abfrage auf:

UPDATE Query1 SET Query1.Field1 = "x" WHERE ([Query1].[Field2]=1);

Offizielle Seite: Zugriffsfehler: "Abfrage ist beschädigt"

Die vorübergehende Behebung dieses Problems hängt von der verwendeten Access-Version ab:
Access 2010-Deinstallationsupdate KB4484127
Access 2013-Deinstallationsupdate KB4484119
Access 2016-Deinstallationsupdate KB4484113
Access 2019, WENN ERFORDERLICH (tbc). Downgrade von Version 1808 (Build 10352.20042) auf Version 1808 (Build 10351.20054)
Office 365 ProPlus-Downgrade von Version 1910 (Build 12130.20344) auf einen früheren Build, siehe https://support.microsoft.com/en-gb/help/2770432/ Wie man zu einer früheren Version von Office 2013 oder Office 2016 zurückkehrt

Wir und unsere Kunden haben in den letzten zwei Tagen damit zu kämpfen und schließlich ein Papier geschrieben, um das Problem zusammen mit einigen Lösungen ausführlich zu erörtern: http://fmsinc.com/MicrosoftAccess/Errors/query_is_corrupt/

Es enthält unsere Erkenntnisse, dass es sich auf Access-Lösungen auswirkt, wenn Aktualisierungsabfragen für lokale Tabellen, verknüpfte Access-Tabellen und sogar verknüpfte SQL Server-Tabellen ausgeführt werden.

Dies wirkt sich auch auf Nicht-Microsoft Access-Lösungen aus, die das Access Database Engine (ACE) verwenden, um mithilfe von ADO eine Verbindung zu Access-Datenbanken herzustellen. Dazu gehören Visual Studio (WinForm) -Apps, VB6-Apps und sogar Websites, auf denen Access-Datenbanken auf Computern aktualisiert werden, auf denen Access oder Office noch nie installiert waren.

Dieser Absturz kann sich sogar auf Microsoft-Apps auswirken, die ACE verwenden, z. B. PowerBI, Power Query, SSMA usw. (nicht bestätigt), und natürlich auf andere Programme wie Excel, PowerPoint oder Word, die VBA zum Ändern von Access-Datenbanken verwenden.

Zusätzlich zur offensichtlichen Deinstallation der fehlerhaften Sicherheitsupdates bieten wir einige Optionen an, wenn eine Deinstallation aufgrund von Berechtigungen oder der Verteilung von Access-Anwendungen an externe Kunden, deren PCs außerhalb Ihrer Kontrolle liegen, nicht möglich ist. Dazu gehört das Ändern aller Update-Abfragen und das Verteilen der Access-Anwendungen mit Access 2007 (Einzelhandel oder Laufzeit), da diese Version von den Sicherheitsupdates nicht betroffen ist.

Verwenden Sie das folgende Modul, um die von Microsoft vorgeschlagene Problemumgehung automatisch zu implementieren (mithilfe einer Abfrage anstelle einer Tabelle). Sichern Sie vorsichtshalber zuerst Ihre Datenbank.

Verwenden AddWorkaroundForCorruptedQueryIssue()Sie diese Option, um die Problemumgehung hinzuzufügen und RemoveWorkaroundForCorruptedQueryIssue()jederzeit zu entfernen.

Option Compare Database
Option Explicit

Private Const WorkaroundTableSuffix As String = "_Table"

Public Sub AddWorkaroundForCorruptedQueryIssue()
    On Error Resume Next

    With CurrentDb
        Dim tableDef As tableDef
        For Each tableDef In .tableDefs
            Dim isSystemTable As Boolean
            isSystemTable = tableDef.Attributes And dbSystemObject

            If Not EndsWith(tableDef.Name, WorkaroundTableSuffix) And Not isSystemTable Then
                Dim originalTableName As String
                originalTableName = tableDef.Name

                tableDef.Name = tableDef.Name & WorkaroundTableSuffix

                Call .CreateQueryDef(originalTableName, "select * from [" & tableDef.Name & "]")

                Debug.Print "OldTableName/NewQueryName" & vbTab & "[" & originalTableName & "]" & vbTab & _
                            "NewTableName" & vbTab & "[" & tableDef.Name & "]"
            End If
        Next
    End With
End Sub

Public Sub RemoveWorkaroundForCorruptedQueryIssue()
    On Error Resume Next

    With CurrentDb
        Dim tableDef As tableDef
        For Each tableDef In .tableDefs
            Dim isSystemTable As Boolean
            isSystemTable = tableDef.Attributes And dbSystemObject

            If EndsWith(tableDef.Name, WorkaroundTableSuffix) And Not isSystemTable Then
                Dim originalTableName As String
                originalTableName = Left(tableDef.Name, Len(tableDef.Name) - Len(WorkaroundTableSuffix))

                Dim workaroundTableName As String
                workaroundTableName = tableDef.Name

                Call .QueryDefs.Delete(originalTableName)
                tableDef.Name = originalTableName

                Debug.Print "OldTableName" & vbTab & "[" & workaroundTableName & "]" & vbTab & _
                            "NewTableName" & vbTab & "[" & tableDef.Name & "]" & vbTab & "(Query deleted)"
            End If
        Next
    End With
End Sub

'From https://excelrevisited.blogspot.com/2012/06/endswith.html
Private Function EndsWith(str As String, ending As String) As Boolean
     Dim endingLen As Integer
     endingLen = Len(ending)
     EndsWith = (Right(Trim(UCase(str)), endingLen) = UCase(ending))
End Function

Sie finden den neuesten Code in meinem GitHub-Repository .

AddWorkaroundForCorruptedQueryIssue()fügt das Suffix _Tableallen Nicht-Systemtabellen hinzu, z. B. würde die Tabelle IceCreamsin umbenannt IceCreams_Table.

Außerdem wird eine neue Abfrage unter Verwendung des ursprünglichen Tabellennamens erstellt, die alle Spalten der umbenannten Tabelle auswählt. In unserem Beispiel würde die Abfrage benannt IceCreamsund die SQL ausführen select * from [IceCreams_Table].

RemoveWorkaroundForCorruptedQueryIssue() macht die umgekehrten Aktionen.

Ich habe dies mit allen Arten von Tabellen getestet, einschließlich externer Nicht-MDB-Tabellen (wie SQL Server). Beachten Sie jedoch, dass die Verwendung einer Abfrage anstelle einer Tabelle in bestimmten Fällen dazu führen kann, dass nicht optimierte Abfragen für eine Backend-Datenbank ausgeführt werden, insbesondere wenn Ihre ursprünglichen Abfragen, die die Tabellen verwendet haben, entweder von schlechter Qualität oder sehr komplex sind.

(Und natürlich ist es abhängig von Ihrem Codierungsstil auch möglich, Dinge in Ihrer Anwendung zu beschädigen. Nachdem Sie überprüft haben, dass das Update im Allgemeinen für Sie funktioniert, ist es nie eine schlechte Idee, alle Ihre Objekte als Text zu exportieren und einen Suchersatz zu verwenden Magie, um sicherzustellen, dass alle Vorkommen von Tabellennamen für die Abfragen und nicht für die Tabellen ausgeführt werden.)

In meinem Fall funktioniert dieses Update weitgehend ohne Nebenwirkungen, ich nur manuell benötigt umbenennen USysRibbons_Tablewieder zu USysRibbons, wie ich es als Systemtabelle nicht markiert war , als ich es in der Vergangenheit erstellt.

Für diejenigen, die diesen Prozess über PowerShell automatisieren möchten , sind hier einige Links aufgeführt, die hilfreich sein können:

Erkennen und Entfernen der fehlerhaften Updates

Hier ist ein PowerShell-Skript verfügbar: https://www.arcath.net/2017/09/office-update-remover , das die Registrierung nach einem bestimmten Office-Update durchsucht (als KB-Nummer übergeben) und es mithilfe eines Aufrufs an entfernt msiexec.exe. Dieses Skript analysiert beide GUIDs aus den Registrierungsschlüsseln, um den Befehl zum Entfernen des entsprechenden Updates zu erstellen.

Eine Änderung, die ich vorschlagen würde, wäre die Verwendung der /REBOOT=REALLYSUPPRESSunter So deinstallieren von KB4011626 und anderen Office-Updates beschriebenen (zusätzliche Referenz: https://docs.microsoft.com/en-us/windows/win32/msi/uninstalling-patches ). Die Befehlszeile, die Sie erstellen, sieht folgendermaßen aus:

msiexec /i {90160000-0011-0000-0000-0000000FF1CE} MSIPATCHREMOVE={9894BF35-19C1-4C89-A683-D40E94D08C77} /qn REBOOT=REALLYSUPPRESS

Der Befehl zum Ausführen des Skripts würde ungefähr so ​​aussehen:

OfficeUpdateRemover.ps1 -kb 4484127

Verhindern Sie die Installation der Updates

Der hier empfohlene Ansatz scheint das Update zu verbergen . Natürlich kann dies manuell erfolgen, aber es gibt einige PowerShell-Skripte, die bei der Automatisierung helfen können. Dieser Link: https://www.maketecheasier.com/hide-updates-in-windows-10/ beschreibt den Prozess im Detail, aber ich werde ihn hier zusammenfassen.

1. Installieren Sie das Windows Update PowerShell-Modul .

2. Verwenden Sie den folgenden Befehl, um ein Update nach KB-Nummer auszublenden:

   Hide-WUUpdate -KBArticleID KB4484127

Hoffentlich hilft dies jemand anderem da draußen.

VBA-Skript für MS-Workaround:

Es wird empfohlen, das fehlerhafte Update nach Möglichkeit zu entfernen (wenn nicht, versuchen Sie es mit meinem Code), zumindest für die MSI-Versionen. Siehe Antwort https://stackoverflow.com/a/58833831/9439330 .

Bei CTR-Versionen (Click-To-Run) müssen Sie alle Office November-Updates entfernen, was zu schwerwiegenden Sicherheitsproblemen führen kann (nicht sicher, ob kritische Korrekturen entfernt werden).

Aus @ Erics Kommentaren:

• Wenn Sie Table.TablenameFormulare zum Binden verwenden, werden sie nicht mehr gebunden, da der frühere Tabellenname jetzt ein Abfragename ist.
• OpenRecordSet(FormerTableNowAQuery, dbOpenTable) wird fehlschlagen (da es jetzt eine Abfrage ist, keine Tabelle mehr)

Vorsicht! Nur schnell gegen Northwind.accdb auf Office 2013 x86 CTR getestet Keine Garantie!

Private Sub RenameTablesAndCreateQueryDefs()
With CurrentDb
    Dim tdf As DAO.TableDef
    For Each tdf In .TableDefs

        Dim oldName As String
        oldName = tdf.Name

        If Not (tdf.Attributes And dbSystemObject) Then 'credit to @lauxjpn for better check for system-tables
            Dim AllFields As String
            AllFields = vbNullString

            Dim fld As DAO.Field

            For Each fld In tdf.Fields
                AllFields = AllFields & "[" & fld.Name & "], "
            Next fld

            AllFields = Left(AllFields, Len(AllFields) - 2)
            Dim newName As String
            newName = oldName

            On Error Resume Next
            Do
                Err.Clear
                newName = newName & "_"
                tdf.Name = newName
            Loop While Err.Number = 3012
            On Error GoTo 0

            Dim qdf As DAO.QueryDef

            Set qdf = .CreateQueryDef(oldName)
            qdf.SQL = "SELECT " & AllFields & " FROM [" & newName & "]"
        End If
    Next
    .TableDefs.Refresh

End With
End Sub

Zum Prüfen:

Private Sub TestError()
With CurrentDb
    .Execute "Update customers Set City = 'a' Where 1=1", dbFailOnError 'works

    .Execute "Update customers_ Set City = 'b' Where 1=1", dbFailOnError 'fails
End With
End Sub

Ich habe das currentDb.Executeund Docmd.RunSQLdurch eine Hilfsfunktion ersetzt. Dadurch kann die SQL-Anweisung vorverarbeitet und geändert werden, wenn eine Aktualisierungsanweisung nur eine Tabelle enthält. Ich habe bereits eine dualTabelle (einzeilig, einspaltig), also habe ich mich für eine fakeTable-Option entschieden.

Hinweis : Dadurch werden Ihre Abfrageobjekte nicht geändert. Es werden nur SQL-Ausführungen über VBA unterstützt.If you would like to change your query objects, use FnQueryReplaceSingleTableUpdateStatements and update your sql in each of your querydefs. Shouldn't be a problem either.

Dies ist nur ein Konzept (If it's a single table update modify the sql before execution). Passen Sie es Ihren Bedürfnissen an. Diese Methode erstellt keine Ersatzabfragen für jede Tabelle (was der einfachste Weg ist, aber seine eigenen Nachteile hat, dh Leistungsprobleme).

+ Punkte: Sie können diesen Helfer auch dann weiter verwenden, wenn MS den Fehler behoben hat. Er ändert nichts. Falls die Zukunft ein anderes Problem mit sich bringt, sind pre-processSie an einem Ort bereit für Ihre SQL. Ich habe mich nicht für die Deinstallation der Update- Methode entschieden, da hierfür der Administratorzugriff erforderlich ist. + Es wird zu lange dauern, bis alle Benutzer die richtige Version erhalten. + Selbst wenn Sie deinstallieren, installiert die Gruppenrichtlinie einiger Endbenutzer das neueste Update erneut. Sie sind wieder beim gleichen Problem.

Wenn Sie Zugriff auf den Quellcode haben use this methodund zu 100% sicher sind, dass kein Endbenutzer das Problem hat.

Public Function Execute(Query As String, Optional Options As Variant)
    'Direct replacement for currentDb.Execute

    If IsBlank(Query) Then Exit Function

    'invalid db options remove
    If Not IsMissing(Options) Then
        If (Options = True) Then
            'DoCmd RunSql query,True ' True should fail so transactions can be reverted
            'We are only doing this so DoCmd.RunSQL query, true can be directly replaced by helper.Execute query, true.
            Options = dbFailOnError
        End If
    End If

    'Preprocessing the sql command to remove single table updates
    Query = FnQueryReplaceSingleTableUpdateStatements(Query)

    'Execute the command
    If ((Not IsMissing(Options)) And (CLng(Options) > 0)) Then
        currentDb.Execute Query, Options
    Else
        currentDb.Execute Query
    End If

End Function

Public Function FnQueryReplaceSingleTableUpdateStatements(Query As String) As String
    ' ON November 2019 Microsoft released a buggy security update that affected single table updates.
    '/programming/58832269/getting-error-3340-query-is-corrupt-while-executing-queries-docmd-runsql

    Dim singleTableUpdate   As String
    Dim tableName           As String

    Const updateWord        As String = "update"
    Const setWord           As String = "set"

    If IsBlank(Query) Then Exit Function

    'Find the update statement between UPDATE ... SET
    singleTableUpdate = FnQueryContainsSingleTableUpdate(Query)

    'do we have any match? if any match found, that needs to be preprocessed
    If Not (IsBlank(singleTableUpdate)) Then

        'Remove UPDATe keyword
        If (VBA.Left(singleTableUpdate, Len(updateWord)) = updateWord) Then
            tableName = VBA.Right(singleTableUpdate, Len(singleTableUpdate) - Len(updateWord))
        End If

        'Remove SET keyword
        If (VBA.Right(tableName, Len(setWord)) = setWord) Then
            tableName = VBA.Left(tableName, Len(tableName) - Len(setWord))
        End If

        'Decide which method you want to go for. SingleRow table or Select?
        'I'm going with a fake/dual table.
        'If you are going with update (select * from T) as T, make sure table aliases are correctly assigned.
        tableName = gDll.sFormat("UPDATE {0},{1} SET ", tableName, ModTableNames.FakeTableName)

        'replace the query with the new statement
        Query = vba.Replace(Query, singleTableUpdate, tableName, compare:=vbDatabaseCompare, Count:=1)

    End If

    FnQueryReplaceSingleTableUpdateStatements = Query

End Function

Public Function FnQueryContainsSingleTableUpdate(Query As String) As String
    'Returns the update ... SET statment if it contains only one table.

    FnQueryContainsSingleTableUpdate = ""
    If IsBlank(Query) Then Exit Function

    Dim pattern     As String
    Dim firstMatch  As String

    'Get the pattern from your settings repository or hardcode it.
    pattern = "(update)+(\w|\s(?!join))*set"

    FnQueryContainsSingleTableUpdate = FN_REGEX_GET_FIRST_MATCH(Query, pattern, isGlobal:=True, isMultiline:=True, doIgnoreCase:=True)

End Function

Public Function FN_REGEX_GET_FIRST_MATCH(iText As String, iPattern As String, Optional isGlobal As Boolean = True, Optional isMultiline As Boolean = True, Optional doIgnoreCase As Boolean = True) As String
'Returns first match or ""

    If IsBlank(iText) Then Exit Function
    If IsBlank(iPattern) Then Exit Function

    Dim objRegex    As Object
    Dim allMatches  As Variant
    Dim I           As Long

    FN_REGEX_GET_FIRST_MATCH = ""

   On Error GoTo FN_REGEX_GET_FIRST_MATCH_Error

    Set objRegex = CreateObject("vbscript.regexp")
    With objRegex
        .Multiline = isMultiline
        .Global = isGlobal
        .IgnoreCase = doIgnoreCase
        .pattern = iPattern

        If .test(iText) Then
            Set allMatches = .Execute(iText)
            If allMatches.Count > 0 Then
                FN_REGEX_GET_FIRST_MATCH = allMatches.item(0)
            End If
        End If
    End With

    Set objRegex = Nothing

   On Error GoTo 0
   Exit Function

FN_REGEX_GET_FIRST_MATCH_Error:
    FN_REGEX_GET_FIRST_MATCH = ""

End Function

Jetzt nur noch CTRL+F

Suchen und ersetzen docmd.RunSQLdurchhelper.Execute

Suchen und ersetzen [currentdb|dbengine|or your dbobject].executedurchhelper.execute

habe Spaß!

Ok, ich melde mich auch hier, denn obwohl dieser Fehler behoben wurde, muss dieser Fix noch vollständig in verschiedenen Unternehmen ausgefüllt werden, in denen die Endbenutzer möglicherweise keine Updates durchführen können (wie bei meinem Arbeitgeber ...).

Hier ist meine Problemumgehung für DoCmd.RunSQL "UPDATE users SET uname= 'bob' WHERE usercode=1". Kommentieren Sie einfach die beleidigende Abfrage aus und geben Sie den folgenden Code ein.

    'DoCmd.RunSQL "UPDATE users SET uname= 'bob' WHERE usercode=1"
    Dim rst As DAO.Recordset
    Set rst = CurrentDb.OpenRecordset("users")
    rst.MoveLast
    rst.MoveFirst
    rst.FindFirst "[usercode] = 1" 'note: if field is text, use "[usercode] = '1'"
    rst.Edit
    rst![uname] = "bob"
    rst.Update
    rst.Close
    Set rst = Nothing

Ich kann nicht sagen, dass es hübsch ist, aber es erledigt den Job.