Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

Grundsätzlich durchlaufe ich alle Blätter in der Ursprungsarbeitsmappe und setze sie dann destsheetin der Zielarbeitsmappe auf das Blatt mit demselben Namen wie das aktuell iterierte in der Ursprungsarbeitsmappe.

Wie kann ich testen, ob dieses Blatt vorhanden ist? Etwas wie:

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

Einige Leute mögen diesen Ansatz nicht, weil die Fehlerbehandlung "unangemessen" verwendet wird, aber ich denke, dass er in VBA als akzeptabel angesehen wird ... Ein alternativer Ansatz besteht darin, alle Blätter zu durchlaufen, bis Sie eine Übereinstimmung finden.

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

Wenn Sie sich speziell nur für Arbeitsblätter interessieren, können Sie einen einfachen Evaluate-Aufruf verwenden:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

Sie benötigen keine Fehlerbehandlung, um dies zu erreichen. Sie müssen lediglich alle Arbeitsblätter durchlaufen und prüfen, ob der angegebene Name vorhanden ist:

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

Da die Suche nach Mitgliedern einer Sammlung ein allgemeines Problem darstellt, finden Sie hier eine abstrahierte Version von Tims Antwort:

Funktion enthält (objCollection As Object, strName as String) als Boolean
    Dim o als Objekt
    On Error Resume Next
    set o = objCollection (strName)
    Enthält = (Err.Number = 0)
    Err.Clear
 Endfunktion

Diese Funktion kann mit jeder Sammlung wie Objekt verwendet werden ( Shapes, Range, Names, Workbooks, etc.).

Verwenden Sie, um das Vorhandensein eines Blattes zu überprüfen If Contains(Sheets, "SheetName") ...

Korrigiert: Ohne Fehlerbehandlung:

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

Wenn jemand VBA vermeiden und testen möchte, ob ein Arbeitsblatt nur in einer Zellformel vorhanden ist, ist dies mit den Funktionen ISREFund möglich INDIRECT:

=ISREF(INDIRECT("SheetName!A1"))

Dies wird zurückkehren , TRUEwenn die Arbeitsmappe ein Blatt namens enthält SheetNameund aus FALSEanderen Gründen .

Ich habe diesen geschrieben:

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

Meine Lösung ähnelt Tims, funktioniert aber auch bei Nicht-Arbeitsblatt-Blättern - Diagrammen

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

.

Wenn Sie den Test in eine Funktion einfügen, können Sie ihn wiederverwenden und haben eine bessere Lesbarkeit des Codes.

Verwenden Sie NICHT "On Error Resume Next", da dies zu Konflikten mit anderen Teilen Ihres Codes führen kann.

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

Viele Jahre zu spät, aber ich musste das nur tun und mochte keine der veröffentlichten Lösungen ... Also habe ich mir eine ausgedacht, alles dank der Magie von (SpongeBob Regenbogen Hände Geste) "Evaluate ()"!

Evaluate("IsError(" & vSheetName & "!1:1)")

Gibt TRUE zurück, wenn Sheet NICHT vorhanden ist. FALSE wenn Blatt existiert. Sie können "1: 1" durch einen beliebigen Bereich ersetzen. Ich rate jedoch davon ab, eine einzelne Zelle zu verwenden. Wenn sie einen Fehler enthält (z. B. # N / A), wird True zurückgegeben.

Kompakte wsExistsFunktion _{^{( ohne auf Fehlerbehandlung angewiesen zu sein!)}}

Hier ist eine kurze und einfache Funktion, die sich nicht auf die Fehlerbehandlung stützt, um festzustellen, ob ein Arbeitsblatt vorhanden ist ( und in jeder Situation ordnungsgemäß als funktionsfähig deklariert ist !).

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

Anwendungsbeispiel:

Im folgenden Beispiel wird ein neues Arbeitsblatt mit dem Namen hinzugefügt myNewSheet, sofern es noch nicht vorhanden ist:

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

Mehr Informationen:

• MSDN: For Each… NextErklärung (VBA)
• MSDN: ExitStatement (VBA)
• MSDN: Vergleichsoperatoren (VBA)

Warum nicht einfach eine kleine Schleife verwenden, um festzustellen, ob das genannte Arbeitsblatt vorhanden ist? Angenommen, Sie haben in der aktuell geöffneten Arbeitsmappe nach einem Arbeitsblatt mit dem Namen "Sheet1" gesucht.

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

Wenn Sie ein Fan von WorksheetFunction.oder nicht aus einem nicht englischen Land mit einem nicht englischen Excel arbeiten, ist dies eine gute Lösung, die funktioniert:

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

Oder in einer Funktion wie dieser:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

Ändern Sie "Daten" in den Blattnamen, auf den Sie testen ...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

Ohne Zweifel, dass die obige Funktion funktionieren kann, habe ich gerade den folgenden Code erhalten, der ziemlich gut funktioniert:

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

Hinweis: Sheets_NameHier fordere ich den Benutzer auf, den Namen einzugeben, damit dies für Sie möglicherweise nicht identisch ist.

Ich habe eine andere Sache gemacht: Löschen Sie ein Blatt nur, wenn es existiert - um keinen Fehler zu erhalten, wenn es nicht existiert:

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

Ich habe mir einen einfachen Weg ausgedacht, aber ich habe kein neues Sub dafür erstellt. Stattdessen habe ich in dem U-Boot, an dem ich gearbeitet habe, nur eine Überprüfung durchgeführt. Angenommen, der gesuchte Blattname ist "Sheet_Exist" und wir möchten ihn nur aktivieren, wenn er gefunden wird:

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

Ich habe auch ein Popup hinzugefügt, wenn das Blatt nicht vorhanden ist.

Ich weiß, dass es ein alter Beitrag ist, aber hier ist eine andere einfache Lösung, die schnell ist.

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

Kurz und sauber:

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

Ich hatte tatsächlich eine einfache Möglichkeit, zu überprüfen, ob das Blatt vorhanden ist, und dann eine Anweisung auszuführen:

In meinem Fall wollte ich das Blatt löschen und habe dann dasselbe Blatt mit demselben Namen neu erstellt, aber der Code wurde unterbrochen, wenn das Programm das Blatt nicht löschen konnte, da es bereits gelöscht wurde

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub