Ich benutze die folgende Funktion

=DAYS360(A2, A35)

um die Differenz zwischen zwei Daten in meiner Spalte zu berechnen. Die Spalte wird jedoch ständig erweitert und ich muss derzeit 'A35' manuell ändern, wenn ich meine Tabelle aktualisiere.

Gibt es eine Möglichkeit (in Google Sheets), die letzte nicht leere Zelle in dieser Spalte zu finden und diesen Parameter dann in der obigen Funktion dynamisch festzulegen?

Es mag einen beredteren Weg geben, aber so habe ich es mir ausgedacht:

Die Funktion zum Suchen der zuletzt ausgefüllten Zelle in einer Spalte lautet:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

Wenn Sie es also mit Ihrer aktuellen Funktion kombinieren, sieht es folgendermaßen aus:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

So finden Sie die letzte nicht leere Zelle, die Sie verwenden können, INDEXund MATCHfunktionieren wie folgt:

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

Ich denke, das ist ein bisschen schneller und einfacher.

Wenn A2: A zusammenhängende Daten enthält, gibt INDEX (A2: A, COUNT (A2: A)) das letzte Datum zurück. Die endgültige Formel lautet

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))

Mein Liebling ist:

=INDEX(A2:A,COUNTA(A2:A),1)

Also, für die Bedürfnisse des OP:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

Wenn die Spalte wie in meinem Fall nur durch zusammenhängend hinzugefügte Daten erweitert wurde, habe ich nur die MAX-Funktion verwendet, um das letzte Datum abzurufen.

Die endgültige Formel lautet:

=DAYS360(A2; MAX(A2:A)) 

Obwohl die Frage bereits beantwortet ist, gibt es einen beredten Weg, dies zu tun.

Use just the column name to denote last non-empty row of that column.

Beispielsweise:

Wenn sich Ihre Daten in befinden A1:A100und Sie in der Lage sein möchten, weitere Spalten zu Spalte A hinzuzufügen, z. B. A1:A105oder sogar A1:A1234später, können Sie diesen Bereich verwenden:

A1:A

Um den letzten nicht leeren Wert in einem Bereich zu erhalten, verwenden wir zwei Funktionen:

• COUNTA
• INDEX

Die Antwort lautet =INDEX(B3:B,COUNTA(B3:B)).

Hier ist die Erklärung:

COUNTA(range) Gibt die Anzahl der Werte in einem Bereich zurück. Wir können dies verwenden, um die Anzahl der Zeilen zu ermitteln.

INDEX(range, row, col)gibt den Wert in einem Bereich an Position zurück rowund col( col=1falls nicht angegeben)

Beispiele:

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

Für das Bild oben wird unser Sortiment sein B3:B. So werden wir zählen , wie viele Werte gibt es in Bereich B3:Bvon COUNTA(B3:B)zuerst. Auf der linken Seite wird es erzeugt, 8da es 8 Werte gibt, während es 9auf der rechten Seite erzeugt wird. Wir wissen auch, dass der letzte Wert in der 1. Spalte des Bereichs liegt, B3:Bdaher muss der colParameter von INDEX1 sein und der rowParameter sollte sein COUNTA(B3:B).

PS : Bitte stimmen Sie der Antwort von @ bloodymurderlive zu , da er sie zuerst geschrieben hat. Ich erkläre sie hier nur.

Hier ist ein anderes:

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

Die letzte Gleichung lautet:

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

Die anderen Gleichungen hier funktionieren, aber ich mag diese, weil sie das Abrufen der Zeilennummer erleichtert, was ich häufiger tun muss. Nur die Zeilennummer würde so aussehen:

=max(arrayformula(if(A:A<>"",row(A:A),"")))

Ich habe ursprünglich versucht, genau dies zu finden, um ein Tabellenkalkulationsproblem zu lösen, konnte jedoch nichts Nützliches finden, das nur die Zeilennummer des letzten Eintrags angegeben hat. Hoffentlich ist dies für jemanden hilfreich.

Dies hat außerdem den zusätzlichen Vorteil, dass es für jeden Datentyp in beliebiger Reihenfolge funktioniert und Sie zwischen Zeilen mit Inhalt leere Zeilen haben können und Zellen mit Formeln, die als "" ausgewertet werden, nicht gezählt werden. Es kann auch wiederholte Werte verarbeiten. Alles in allem ist es der Gleichung sehr ähnlich, die hier max ((G: G <> "") * row (G: G)) verwendet, aber das Herausziehen der Zeilennummer ein wenig erleichtert, wenn Sie danach suchen .

Wenn Sie alternativ ein Skript auf Ihr Blatt setzen möchten, können Sie es sich leicht machen, wenn Sie vorhaben, dies häufig zu tun. Hier ist dieser Scirpt:

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

Hier können Sie einfach Folgendes eingeben, wenn Sie die letzte Zeile auf demselben Blatt haben möchten, das Sie gerade bearbeiten:

=LASTROW()

oder wenn Sie die letzte Zeile einer bestimmten Spalte aus diesem Blatt oder einer bestimmten Spalte aus einem anderen Blatt möchten, können Sie Folgendes tun:

=LASTROW("Sheet1","A")

Und für die letzte Zeile eines bestimmten Blattes im Allgemeinen:

=LASTROW("Sheet1")

Um die tatsächlichen Daten zu erhalten, können Sie entweder indirekt verwenden:

=INDIRECT("A"&LASTROW())

oder Sie können das obige Skript in den letzten beiden Rückgabezeilen ändern (die letzten beiden, da Sie sowohl das Blatt als auch die Spalte einfügen müssten, um den tatsächlichen Wert aus einer tatsächlichen Spalte zu erhalten) und die Variable durch die folgende ersetzen:

return sheet.getRange(column + final).getValue();

und

return sheet.getRange(column + lastRow).getValue();

Ein Vorteil dieses Skripts besteht darin, dass Sie auswählen können, ob Sie Gleichungen einschließen möchten, die mit "" bewertet werden. Wenn keine Argumente hinzugefügt werden, werden Gleichungen gezählt, die mit "" bewertet werden. Wenn Sie jedoch ein Blatt und eine Spalte angeben, werden sie jetzt gezählt. Es gibt auch viel Flexibilität, wenn Sie bereit sind, Variationen des Skripts zu verwenden.

Wahrscheinlich übertrieben, aber alles möglich.

Was ist mit dieser Formel, um den letzten Wert zu erhalten:

=index(G:G;max((G:G<>"")*row(G:G)))

Und dies wäre eine endgültige Formel für Ihre ursprüngliche Aufgabe:

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

Angenommen, Ihr ursprüngliches Datum ist in G10.

Ich bin einen anderen Weg gegangen. Da ich weiß, dass ich einer Zeile / Spalte nacheinander etwas hinzufügen werde, finde ich die letzte Zeile heraus, indem ich zuerst die Felder mit Daten zähle. Ich werde dies mit einer Kolumne demonstrieren:

=COUNT(A5:A34)

Nehmen wir also an, dass 21 zurückgegeben wurde. A5 ist 4 Zeilen tiefer, also muss ich die 21. Position von der 4. Reihe nach unten bekommen. Ich kann dies mit inderect tun, wie folgt:

=INDIRECT("A"&COUNT(A5:A34)+4)

Es geht darum, die Anzahl der Zeilen mit Daten zu ermitteln und mir eine Zahl zurückzugeben, die ich als Indexmodifikator verwende.

für eine Reihe:

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

für eine Spalte:

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))

Dies scheint die einfachste Lösung zu sein, die ich gefunden habe, um den letzten Wert in einer ständig wachsenden Spalte abzurufen:

=INDEX(A:A,COUNTA(A:A),1)

Das funktioniert bei mir. Abrufen des letzten Werts der Spalte A in Google Sheet:

=index(A:A,max(row(A:A)*(A:A<>"")))

(Es werden auch leere Zeilen dazwischen übersprungen, falls vorhanden.)

Berechnen Sie die Differenz zwischen dem letzten Datum in Spalte A und dem Datum in Zelle A2.

=MAX(A2:A)-A2

Dies gibt den Inhalt der letzten Zelle:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

Dies gibt die Adresse der letzten Zelle an:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Dies gibt die Zeile der letzten Zelle an:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Vielleicht bevorzugen Sie ein Skript. Dieses Skript ist viel kürzer als das große, das oben von jemand anderem gepostet wurde:

Gehen Sie zum Skripteditor und speichern Sie dieses Skript:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

Wenn dies erledigt ist, müssen Sie dies nur in eine Zelle eingeben:

=getLastRow(A:A)

Die Art und Weise, wie ein Amateur dies tut, ist "= CONCATENATE (" A ", COUNTUNIQUE (A1: A9999))", wobei A1 die erste Zelle in der Spalte ist und A9999 weiter unten in dieser Spalte liegt, als ich jemals erwartet habe, Einträge zu haben. Dieses resultierende A # kann bei Bedarf mit der INDIRECT-Funktion verwendet werden.

Um die letzte nicht leere Zeilennummer zu finden (wobei Leerzeichen zwischen ihnen zulässig sind), habe ich unten die Spalte durchsucht A.

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))