Wie kann ich ein bestimmtes Zeichen in einer Variablen in einer Batch-Datei maskieren?

Ich habe dieses Skript erstellt, aber es funktioniert nicht:

for /R %%f in (*.mkv) do (
 ffmpeg -i "%%f" -vf subtitles="%%~nf.mkv" -acodec copy "%%~nf.mp4"
 )

 PAUSE

Nachdem ich nach dem Problem gesucht habe, habe ich festgestellt, dass das Problem der Name der Datei ist, die eckigen Klammern müssen ausgeblendet werden (zum Beispiel [1080p]coolvid.mp4sollten \[1080p\]coolvid.mp4. Wie kann ich das mit dem Namen der Datei machen (dh %% f)?

Die eckigen Klammern müssen entfernt werden

Verwenden Sie die folgende Batchdatei:

@echo off
setlocal
setlocal enabledelayedexpansion
for /r %%f in (*.mkv) do (
  set _a=%%~nf
  set _b=!_a:[=\[!
  set _name=!_b:]=\]!
  set _c=%%f
  set _d=!_c:[=\[!
  set _fullname=!_d:]=\]!
  ffmpeg -i "!_fullname!" -vf subtitles="!_name!.mkv" -acodec copy "!_name!.mp4"
  )
endlocal
pause

Weitere Lektüre

• Ein AZ-Index der Windows CMD-Befehlszeile - Eine hervorragende Referenz für alle Dinge, die mit der Windows CMD-Zeile zu tun haben.
• enabledelayedexpansion - Die verzögerte Erweiterung bewirkt, dass Variablen zur Ausführungszeit und nicht zur Analysezeit erweitert werden.
• for / r - Durchlaufen von Dateien (Recurse-Unterordner).
• set - Anzeigen, Festlegen oder Entfernen von CMD-Umgebungsvariablen. Mit SET vorgenommene Änderungen bleiben nur für die Dauer der aktuellen CMD-Sitzung erhalten.
• Variable bearbeiten / ersetzen - Bearbeiten und ersetzen Sie die Zeichen, die einer Zeichenfolgenvariablen zugewiesen sind.
• FFmpeg-Dokumentation: Zitieren und Escapieren - Details, die spezifisch für zitieren und Escapieren sindffmpeg .

BEARBEITEN: Der ursprüngliche Code schlägt fehl, wenn Sie eine Datei (oder einen Dateipfad) mit dem !Zeichen ausführen, da die verzögerte Erweiterung aktiviert ist und die Variable FOR vor der verzögerten Erweiterung erweitert wird. Namen mit !werden also verfälscht.

Dies lässt sich leicht beheben, indem die verzögerte Erweiterung in der Schleife ein- und ausgeschaltet wird, sodass keine FOR-Variablen erweitert werden, während die verzögerte Erweiterung aktiviert ist.

@echo off
setlocal disableDelayedExpansion
for /r %%f in (*.mkv) do (
  set _a=%%~nf
  set _c=%%f
  setlocal enableDelayedExpansion
  set _b=!_a:[=\[!
  set _name=!_b:]=\]!
  set _d=!_c:[=\[!
  set _fullname=!_d:]=\]!
  ffmpeg -i "!_fullname!" -vf subtitles="!_name!.mkv" -acodec copy "!_name!.mp4"
  endlocal
)
endlocal
pause