Wie extrahiere ich nur die Zahlen, die sich in einem bestimmten Muster befinden, aus gemischtem Text in Excel?

Ich muss ein bestimmtes Zahlenmuster aus gemischtem Text in Excel extrahieren. Überlegungen:

1. Die zu extrahierende Zahl hat immer das Muster 99.99.999.999
2. Der String, in dem er enthalten ist, ist unterschiedlich lang, und die Position der zu extrahierenden Zahlen variiert ebenfalls.
3. Am Anfang oder Ende der erforderlichen Zahlen befinden sich keine Zeichen, anhand derer sie extrahiert werden können

Beispiele:

01.11.202.037.2011_20171017150732.pdf  
01.26.304.012.09.re_20170621163250.pdf  
01.36.402.010 MAI 2011.pdf  
2011.mai.01.02.203.001_20170802112610.pdf  
lease_20161104110041.pdf  
re.01.02.203.001.2012_20171019085424.pdf  
16.20.116.014.14re_20170621161637.pdf  

Ergebnis sollte sein:

01.11.202.037  
01.26.304.012  
01.36.402.010  
01.02.203.001  
NA  
01.02.203.001  
16.20.116.014 

Hier ist etwas mit regulären Ausdrücken. Es funktioniert mit all Ihren Beispielen und prüft auch, ob das erste und das letzte Segment nicht mehr als zwei oder drei Ziffern haben:

Option Explicit
Function ExtractNumPattern(S As String) As String
    Dim RE As Object, MC As Object
    Const sPat As String = "(?:^|\D)(\d{2}\.\d{2}\.\d{3}\.\d{3})(?:\D|$)"

Set RE = CreateObject("vbscript.regexp")
With RE
    .Global = False
    .Pattern = sPat
    .MultiLine = True
    If .Test(S) = True Then
        Set MC = .Execute(S)
        ExtractNumPattern = MC(0).submatches(0)
    Else
        ExtractNumPattern = "NA"
    End If
End With
End Function

Das Regex-Muster sollte ziemlich klar sein, außer vielleicht für den Anfang und das Ende.

Der erste Teil (?:^|\D) Stellt sicher, dass dem Wert entweder eine Ziffer oder der Zeilenanfang vorangestellt wird.

Der letzte Teil (?:\D|$) Stellt sicher, dass dem Wert entweder eine Ziffer oder das Ende der Zeile folgt.

Solch ein Overkill, warum gehst du immer zu VBA, würde ich einfach tun

=MID(A1,SEARCH("??.??.???.???",A1),13)

Ziehen Sie die Formel nach unten, oh ja, und fügen Sie eine Fehlerkorrektur für Werte ohne diese ein

=IFERROR(MID(A1,SEARCH("??.??.???.???",A1),13),"NA")

Wenn Sie eine ziemlich einfach zu verfolgende VBA-Funktion möchten,

Option Explicit

Sub TestIt()
  Dim c As Range
  For Each c In ActiveSheet.UsedRange
    Debug.Print c, ParsedAddr(c)
  Next c
End Sub

Function ParsedAddr(c As Range) As String
  Dim i As Long, iLen As Long

  iLen = Len(c)
  For i = 1 To iLen - 12
    If IsNumeric(Mid(c, i, 1)) Then                              '9
      If IsNumeric(Mid(c, i + 1, 1)) Then                        '99
        If Mid(c, i + 2, 1) = "." Then                           '99.
          If IsNumeric(Mid(c, i + 3, 1)) Then                    '99.9
            If IsNumeric(Mid(c, i + 4, 1)) Then                  '99.99
              If Mid(c, i + 5, 1) = "." Then                     '99.99.
                If IsNumeric(Mid(c, i + 6, 1)) Then              '99.99.9
                  If IsNumeric(Mid(c, i + 7, 1)) Then            '99.99.99
                    If IsNumeric(Mid(c, i + 8, 1)) Then          '99.99.999
                      If Mid(c, i + 9, 1) = "." Then             '99.99.999.
                        If IsNumeric(Mid(c, i + 10, 1)) Then     '99.99.999.9
                          If IsNumeric(Mid(c, i + 11, 1)) Then   '99.99.999.99
                            If IsNumeric(Mid(c, i + 12, 1)) Then '99.99.999.999
                              Exit For
                            End If
                          End If
                        End If
                      End If
                    End If
                  End If
                End If
              End If
            End If
          End If
        End If
      End If
    End If
  Next i
  If i < iLen - 11 Then
    ParsedAddr = Mid(c, i, 13)
  Else
    ParsedAddr = "NA"
  End If
End Function

Mit VBA können Sie in der Tat alles verschachteln, was Sie wollen. Sie können diesen Code mithilfe von Subroutinen massiv komprimieren - z. Suche nach Zeichen im Format "99". oder "999". - aber obwohl es nicht "eng" ist, ist es hübsch :) Ich lasse es nackt, also ist es extrem einfach zu folgen.

Ich habe dies als Funktion geschrieben, damit es angepasst werden kann, um geparste Zeichenfolgen in Zellen auszugeben.

Diese Frage hat mich wirklich beschäftigt, also habe ich beschlossen, es selbst zu versuchen. ich denke, dass Ron Rosenfeld Die Antwort von ist hübsch einfach und vielleicht ein bisschen elaganter; Überlegen Sie sich diese Methode also unbedingt zuerst.

Ich verwende die folgende Methodik :

1. Verwandle die Schnur in ein einfaches Muster; Perioden gleich 0 s und alle anderen Zeichen sind gleich 1 s.
2. Suchen Sie dann nach dem Muster, nach dem das OP fragt. ##. ##. ###. ### = 1101101110111
3. Die Suche gibt den Startindex des Musters zurück - von diesem Index werden 13 Zahlen zurückgegeben.

Der zusätzliche Code dient wie üblich dazu, Fehler abzufangen, die Leistung zu verbessern (getestet mit 5.000 doppelten Datensätzen) und die Logik zu verbessern.

Unten sehen Sie ein Bild des xlsm-Layouts:

BILD-LINK

Bitte besuchen Sie diese Code Review Beitrag für eine genauere Analyse von Thomas Inzina und Zeiger von AJD , der dazu beigetragen hat, die Qualität des folgenden Codes zu verbessern.

Sub PatternScrub()

Dim Pattern As String
Dim x As Integer
Dim data As Variant
Dim Target As Range

With ThisWorkbook.Worksheets("Sheet1")
    Set Target = .Range("A1", .Range("A" & .Rows.Count).End(xlUp))
End With

data = Target.Value

    PerformanceBoost True

        For x = 1 To UBound(data)
            If data(x, 1) Like "*##.##.###.###*" Then
                data(x, 1) = getPatternValue(CStr(data(x, 1)))
            Else
                data(x, 1) = "NA"
            End If
        Next

        Target.Offset(0, 1).Value = data

    PerformanceBoost False

End Sub

Private Function Pattering(ByVal Target As String) As String

Dim i As Integer

    For i = 1 To Len(Target)
       Mid(Target, i, 1) = IIf(Mid(Target, i, 1) = ".", 0, 1)       'TURNS THE STRING INTO 1s AND 0s
    Next

Pattering = Target

End Function

Private Function PatternIndex(ByVal Pattern As String) As Integer

    On Error Resume Next
    PatternIndex = Application.WorksheetFunction.Search("1101101110111", Pattern)       ' MATCHES THE PATTERN AND RETURNS THE FIRST INDEX

End Function

Private Function getPatternValue(Text As String) As String

    Dim x As Long
    x = PatternIndex(Pattering(Text))
    getPatternValue = Mid(Text, x, 13)

End Function

Sub PerformanceBoost(TurnOn As Boolean)

    With Application
        .Calculation = IIf(Turn, xlCalculationManual, xlCalculationAutomatic)
        .ScreenUpdating = Not TurnOn
        .DisplayStatusBar = Not TurnOn
        .EnableEvents = Not TurnOn
    End With

End Sub