Ich bin auf der Suche nach einem Tool, das die inkrementelle Rückwärtssuche mit einfacher Unterstützung für reguläre Ausdrücke (oder nur für mehrere Übereinstimmungen) ermöglicht. Wenn ich zum Beispiel den Befehl 'foo bar baz' suchen möchte, könnte ich folgendermaßen vorgehen, um den Befehl schnell zu finden:

CRTL-R (Startet die Suche) Geben Sie "foo" ein (entspricht dem letzten Befehl mit "foo") Geben Sie weiterhin "foo | baz" ein (entspricht dem letzten Befehl mit "foo" UND "baz").

Gibt es so etwas? Wenn nein, wie könnte ich es selbst implementieren?

Benutzerdefiniertes Widget history-incremental-multi-searchfürzsh

Konfiguration

Erstellen Sie ein Verzeichnis und fügen Sie es in Ihr $fpathVerzeichnis ein. Ich habe beispielsweise ein Verzeichnis erstellt ~/.zsh/functionsund die Zeile fpath=($HOME/.zsh/functions $fpath)in meinem .zshrc.

Fügen Sie Folgendes in eine Datei ein, die history-incremental-multi-searchin diesem Verzeichnis benannt ist.

emulate -L zsh
setopt extended_glob

local oldbuffer=$BUFFER
local -i oldcursor=$CURSOR

local dir                # search direction
local chars              # input buffer
local -a words           # search terms
local -a found           # all history items that match first term
local -i hindex=$HISTNO  # current 
local -i lmatch          # last matched history item (for prev/next)

if [[ $WIDGET == *forward* ]]; then
    dir=fwd
else
    dir=bck
fi

function find-next {
    # split the input buffer on spaces to get search terms
    words=(${(s: :)chars})

    # if we have at least one search term
    if (( $#words )); then
        # get all keys of history items that match the first
        found=(${(k)history[(R)*$words[1]*]})
        if (( $#found )); then
            # search in widget direction by default
            # but accept exception in $1 for "prev match"
            search-${1:-$dir}
        else
            # no matches
            lmatch=$HISTNO
        fi
    else
        # no search terms
        lmatch=$HISTNO
        BUFFER=$oldbuffer
        CURSOR=$oldcursor
    fi
}

function search-fwd {
    # search forward through matches
    local -i i
    for (( i = $#found; i > 0; i-- )); do
        # but not before hindex as we're searching forward
        if [[ $found[$i] -gt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function search-bck {
    # search backward through matches
    local -i i
    for (( i = 1; i <= $#found; i++ )); do
        # but not beyond hindex as we're searching backward
        if [[ $found[$i] -lt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function set-match {
    # match history item against all terms and select it if successful
    local match=1
    local -i i
    for (( i = 2; i <= $#words; i++ )); do
        if [[ $history[$1] != *$words[$i]* ]]; then
            match=0
            break
        fi
    done
    if [[ $match -ne 0 ]]; then
        lmatch=$1
        BUFFER=$history[$1]
        CURSOR=$#BUFFER
        break
    fi
}

# display sub prompt
zle -R "${dir}-i-search-multi:"

# handle input keys
while read -k; do
    case $REPLY in
        # next
        $'\C-n' )
            hindex=$lmatch
            find-next
            ;;
        # prev
        $'\C-p' )
            hindex=$lmatch
            if [[ $dir == fwd ]]; then
                find-next bck
            else
                find-next fwd
            fi
            ;;
        # break
        $'\e' | $'\C-g' )
            BUFFER=$oldbuffer
            CURSOR=$oldcursor
            break
            ;;
        # accept
        $'\C-m' | $'\C-j' )
            if [[ $lmatch -eq $HISTNO ]]; then
                BUFFER=$oldbuffer
                CURSOR=$oldcursor
            else
                HISTNO=$lmatch
            fi
            break
            ;;
        # erase char
        $'\C-h' | $'\C-?' )
            chars=$chars[1,-2]
            hindex=$HISTNO
            find-next
            ;;
        # erase word
        $'\C-w' )
            if [[ $chars =~ \  ]]; then
                chars=${chars% *}
            else
                chars=
            fi
            hindex=$HISTNO
            find-next
            ;;
        # kill line
        $'\C-u' )
            chars=
            hindex=$HISTNO
            find-next
            ;;
        # add unhandled chars to buffer
        * )
            chars=${chars}${REPLY}
            hindex=$HISTNO
            find-next
            ;;
    esac

    zle -R "${dir}-i-search-multi: $words"
done

Geben Sie dies ein oder beziehen Sie es von Ihrem .zshrc:

autoload -U history-incremental-multi-search

# make new widgets from function
zle -N history-incremental-multi-search-backward history-incremental-multi-search
zle -N history-incremental-multi-search-forward history-incremental-multi-search

# bind the widgets to keys
bindkey '^Xr' history-incremental-multi-search-backward
bindkey '^Xs' history-incremental-multi-search-forward

Verwenden

Sie sollen nun eine rückwärts inkrementelle Suche mit zu initiieren fähig sein Ctrl+X, rvorwärts mit Ctrl+X, s.

Geben Sie Ihre Suchbegriffe durch ein Leerzeichen getrennt ein. Folgende Tasten stehen zur Steuerung zur Verfügung:

• ← Backspace: Zeichen löschen

• Ctrl+W: Wort löschen

• Ctrl+U: kill line

• Ctrl+N: nächstes Spiel

• Ctrl+P: vorheriges Spiel

• Ctrl+G/ Esc: Suche abbrechen

• Enter: akzeptieren

Diese Lösung kann wahrscheinlich erheblich vereinfacht werden. Es ist eher ein funktionaler Proof of Concept mit viel Raum für Verbesserungen.

Sie können Ihre Geschichte durchgehen:

history | egrep '(foo|baz)'

Ich hoffe das hilft.