Wie wählt man einen Multiplikator basierend auf bestimmten Zelleingaben in Excel?

Ich benötige Unterstützung beim Schreiben einer Excel-Formel für Folgendes:

In die Zelle wird A28eine der folgenden Angaben eingegeben: LIN, LOX, LAR, CO2, GH2, GN2 oder GO2

Abhängig davon, was in Zelle A28 eingegeben wird, wird ein Umrechnungswert vorliegen, der mit dem Wert in Zelle D63 multipliziert werden muss, und das Produkt wird in Zelle S63 eingegeben

Beispiel:

WENN A28 = LIN,
MUSS DANN ZELLE D63 MIT 13,80 MULTIPLIZIERT WERDEN
UND DIESES PRODUKT IN ZELLE S63 EINGESTELLT WERDEN

LIN = 13.80  
LOX = 12.08  
LAR = 9.671  
CO2 = 1.0  
GH2 =1.0  
GN2 = 1.0  
GO2 = 1.0  

Jede Hilfe wird sehr geschätzt!

Sie benötigen eine separate Tabelle mit allen möglichen Werten (LIN, LOX usw.) in einer Spalte und den zugehörigen Umrechnungsfaktoren (13.80, 12.08 usw.) in der nächsten Spalte. Wenn sich diese Tabelle in B1: C7 befindet, würden Sie in S63 Folgendes eingeben:

=D63*VLOOKUP(A28,B1:C7,2,FALSE)

Wenn Sie die Werte lieber hart in die Formel codieren möchten, als eine separate Nachschlagetabelle zu erstellen, können Sie in S63 die folgende weniger elegante Formel verwenden:

=IF(ISBLANK(A28),"",IF(A28="LIN",13.80,IF(A28="LOX",12.08,IF(A28="LAR",9.671,1.0))))

Versuchen Sie, diese Formel in S63 einzugeben

=D63*SUM(
(A28="LIN")*13.8,
(A28="LOX")*12.08,
(A28="LAR")*9.671,
(A28="CO2")*1,
(A28="GH2")*1,
(A28="GN2")*1,
(A28="GO2")*1)

So wird ausgewertet, ob A28 "LOX" enthält:

Wenn Sie etwas abenteuerlustig sind, können Sie diese Formeln in S63 ausprobieren :

=D63*CHOOSE(MATCH(A28,{"LIN";"LOX";"LAR";"CO2";"GH2";"GN2";"GO2"},0),13.8,12.08,9.671,1,1,1,1)

oder

=D63*VLOOKUP(A28,{"LIN",13.8;"LOX",12.08;"LAR",9.671;"CO2",1;"GH2",1;"GN2",1;"GO2",1},2,0)