Globaler Hotkey zum Ein- / Ausblenden einer bestimmten App in OS X? [Duplikat]

10

Mögliches Duplizieren:
Starten Sie eine OS X-App mit einer Tastenkombination

Ist es möglich, einen globalen Hotkey zum Ein- / Ausblenden einer bestimmten App in OS X zu definieren?

Zum Beispiel möchte ich Safari mit Cmd+ ein- / ausblenden können Space.

macos hotkeys Roman Dolgiy
quelle
Im Zusammenhang mit Starten einer OS X-App mit einer Tastenkombination - Super User . Ich habe meine Antwort auf diese Frage so bearbeitet, dass sie Apps von Drittanbietern enthält, die Auslöser für das Ein- und Ausblenden unterstützen. Ich habe auch ein AppleScript zum Ein- oder Ausblenden einer App hinzugefügt.
Lri

Antworten:

7

Öffnen Sie Automator , wählen Sie, um einen Dienst zu erstellen , und konfigurieren Sie ihn so, dass er in keiner Anwendung Eingaben erhält .

Doppelklicken Sie in der Bibliothek auf Dienstprogramme »AppleScript ausführen und geben Sie Folgendes in den großen Textbereich ein:

on run {input, parameters}

    tell application "System Events"
        set names to name of application processes
        if names contains "Safari" then
            tell application process "Safari"
                if visible then
                    set visible to false
                else
                    # use the following to simply have it reappear:
                    set visible to true
                    # use the following to focus Safari:
                    tell application "Safari" to activate
                end if
            end tell
        else
            display dialog "Safari is not running"
        end if
    end tell

    return input
end run

Speichern Sie unter einem beliebigen Namen. Weisen Sie in den Systemeinstellungen »Tastatur» Tastaturkürzel »Dienste eine Tastenkombination zu . Denken Sie daran, die Spotlight-Verknüpfung zu deaktivieren Cmd-Space.

Daniel Beck
quelle
2
Stattdessen display dialogkönnen Sie es alternativ tell application "Safari" to activatestarten, wenn es nicht ausgeführt wird.
Daniel Beck
3

Speichern Sie im AppleScript Editor und weisen Sie eine Verknüpfung zum Ausführen eines Skripts in OS X zu

tell application (path to frontmost application as text)
    if name is "TextEdit" then
        set bid to id
        tell application "System Events" to tell (process 1 where bundle identifier is bid)
            set visible to false
        end tell
    else
        tell application "TextEdit"
            reopen
            activate
        end tell
    end if
end tell
  • Wenn sich die Zielanwendung derzeit ganz vorne befindet, blenden Sie sie aus
  • Andernfalls aktivieren Sie es
Lri
quelle
Das Verhalten dieses Skripts ist wie folgt: Wenn TextEdit die vorderste Anwendung ist, wird es ausgeblendet, andernfalls wird es nach vorne gebracht. Dieses Skript versteckt die Anwendung also nicht, wenn sie sichtbar, aber nicht ganz vorne ist, sondern bringt sie nach vorne.
Daniel Beck
Cleveres Verhalten. Mir fehlte nur die Erklärung, wie sich die Verknüpfung in Ihrem Beitrag verhält - ich denke, das wäre hilfreich.
Daniel Beck
Vielen Dank! Ich habe Daniels Antwort markiert, als er der erste war.
Roman Dolgiy
-3

CMD + W blendet Fenster aus. Dies funktioniert global. Um jedoch zu ihnen zurückzukehren, müssen Sie auf die Dock-Symbole klicken. In einem Browser wird jedoch die Registerkarte geschlossen.

Aleksandr Vysockij
quelle
Cmd + W schließt Fenster.
Daviesgeek
Darüber hinaus fragt der Benutzer nach Anwendungen , nicht nach Windows . Unter OS X gibt es einen großen Unterschied.
Daniel Beck