Fenster mit der Tastatur verschieben… schneller?

Ich verwende gerne Tastaturkürzel, weil sie schneller sind, da ich nicht gezwungen bin, meine Hände von der Tastatur zu entfernen.

In Windows kann ich sie verwenden, um Fenster auf dem Desktop zu verschieben:

1. Drücken Sie Alt+ Space, um das allgemeine Windows-Menü zu öffnen
2. Drücken Sie M, um den Befehl "Verschieben" auszuwählen
3. Navigieren Sie mit den Cursortasten zur Fensterposition
4. Bestätigen Sie die neue Position mit Enter

Um eine bessere Genauigkeit zu erzielen, kann ich außerdem Ctrlwährend der Navigation halten .

Das Problem ist nun, dass der normale "Schritt" beim Verschieben etwa 20 Pixel beträgt und mein Desktop ziemlich groß ist, so dass das "Gehen" über den gesamten Weg ziemlich lange dauert. Diese Art von macht den Zweck der Verwendung der Tastatur für diese Aufgaben zunichte.

Ist es möglich, die Größe dieses Schritts so zu ändern, dass weniger Schritte erforderlich sind, um dieselbe Strecke zu gehen? (Ich stelle mir eine versteckte Einstellung in der Windows-Registrierung vor ...?)

Ich habe versucht, Altwährend der Navigation zu halten, aber es scheint keinen Einfluss auf die Geschwindigkeit zu haben.

Wenn Sie die Fensterparadigmen in Richtung dynamischer Kacheln komplett überarbeiten möchten , ziehen Sie ein AutoHotkey-Skript mit dem Namen " bug.n " in Betracht . Sie werden es mögen, wenn Sie Fenster lieber über die Tastatur bearbeiten möchten.

Das Bewegen mit der Tastatur wie Sie ist präzise, ​​aber mühsam.

Wenn Sie Ihre Fenster normalerweise an bestimmte Positionen und Größen verschieben, versuchen Sie es mit GridMove . Sie können entweder Ihr eigenes Raster definieren (Fensterposition und -größen) oder die vordefinierten verwenden. Jedes davon wird als Kachel bezeichnet. Danach können Sie jedes aktive Fenster ausrichten, indem Sie Win + 2 drücken, wobei 2 die Kachelnummer ist, in die es einrasten soll. Drücken Sie Win + G, um die Kacheln und ihre Nummern im aktuellen Raster anzuzeigen.

Unter Windows 7 können Sie die Fenster mit der Windows-Taste + Pfeiltaste verschieben.

Ich bin nicht sicher, wie viele Pixel sie gleichzeitig verschieben, aber es sind mehr als 20.

Nicht ganz zum Thema, aber ich denke, es ist immer noch relevant und es lohnt sich, es zu teilen.

Ich verwende AutoHotKey und ein "KDEStyle" -Skript , das ich vor langer Zeit gefunden habe und das ich angepasst habe, um die Verwendung der Maus für diesen Zweck zu verbessern.

• Win + Left Click
  • Ermöglicht das Verschieben des Fensters durch Klicken auf eine beliebige Stelle im Fenster .
• Win + Right Click
  • Ermöglicht es Ihnen, die Größe des Fensters mithilfe der nächsten Ecke zu ändern und erneut auf eine beliebige Stelle darin zu klicken .

Dies reduziert die erforderliche Präzision erheblich und macht es meiner Meinung nach viel einfacher und schneller, die Maus für solche Zwecke zu verwenden.

#LButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,,,ahk_id %KDE_id%
    loop {
        GetKeyState,KDE_Button,LButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        KDE_WinX2 := (KDE_WinX1 + KDE_X2)
        KDE_WinY2 := (KDE_WinY1 + KDE_Y2)
        WinMove,ahk_id %KDE_id%,,%KDE_WinX2%,%KDE_WinY2%
    }
    return

#RButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
    if (KDE_X1 < KDE_WinX1 + KDE_WinW / 2) {
        KDE_WinLeft := 1
    } else {
        KDE_WinLeft := -1
    }
    if (KDE_Y1 < KDE_WinY1 + KDE_WinH / 2) {
        KDE_WinUp := 1
    } else {
        KDE_WinUp := -1
    }
    loop {
        GetKeyState,KDE_Button,RButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        WinMove,ahk_id %KDE_id%,, KDE_WinX1 + (KDE_WinLeft+1)/2*KDE_X2
                                , KDE_WinY1 +   (KDE_WinUp+1)/2*KDE_Y2
                                , KDE_WinW  -     KDE_WinLeft  *KDE_X2
                                , KDE_WinH  -       KDE_WinUp  *KDE_Y2
        KDE_X1 := (KDE_X2 + KDE_X1)
        KDE_Y1 := (KDE_Y2 + KDE_Y1)
    }
    return

Standardmäßige Windows-Tastaturkombinationen ergänzen dies und ermöglichen Ihnen Folgendes:

• Win+ Up/Down
  • Maximieren / Wiederherstellen / Minimieren
• Win+ Left/Right
  • Ändern Sie die Größe auf die linke / rechte Bildschirmhälfte
• Win+ Shift+ Left/Right
  • Bewegen Sie einen Monitor nach links / rechts
• usw...