Wie kann ich Google Chrome dazu bringen, mit dem Mausrad zwischen Tabs zu wechseln?

Zu Hause führe ich Fedora 17 aus und bin es gewohnt, mit dem Mausrad über die Registerkartenleiste schnell durch geöffnete Registerkarten zu scannen. Es ist jetzt eine sehr natürliche Geste für mich.

Mindestens einmal in der Woche (normalerweise montags) versuche ich, die gleiche Technik bei Chrome auf einem MacBook Pro anzuwenden, aber die Registerkarten rühren sich nicht. Das macht mich langsam verrückt.

Hat jemand eine Lösung, mit der ich das Scrollrad zum Wechseln der Tabs in Google Chrome für OSX verwenden kann?

(Ich habe den folgenden Google Code-Thread gefunden, aber der vorgeschlagene Fix behebt das Problem nicht, soweit ich das beurteilen kann. Http://code.google.com/p/chrome-convenience-extension/issues/detail?id= 31 )

Die Erweiterung Chrome Toolbox könnte Sie interessieren:

Ich habe es nicht unter OSX getestet, aber es funktioniert unter Windows 7 und es sollte dort keine Kompatibilitätsprobleme geben.

Es wurde eine Lösung in einem Google Groups-Thread gefunden. Verwenden Sie AutoHotKey mit dem folgenden Skript:

;; Wheel Scroll Tabs for Google Chrome 

#IfWinActive ahk_class Chrome_WidgetWin_1 
 ~$WheelDown:: 
 ~$WheelUp:: 
    MouseGetPos,, yaxis 
    IfGreater,yaxis,23, Return 
    IfEqual,A_ThisHotkey,~$WheelDown, Send ^{PgDn} 
                                 Else Send ^{PgUp} 
Return 
#IfWinActive

Hinweis: Ich habe es geändert, Chrome_WidgetWin_1weil das bei mir funktioniert hat. Wenn das bei Ihnen nicht funktioniert, versuchen Sie es mitChrome_WidgetWin_0

Quelle

Wenn Sie Chrome 32+ verwenden, überprüfen Sie diese Lösung mit AutoHotKey (kompiliertes Skript). Chrome Toolbox funktioniert in Chrome über 31 nicht.

https://plus.google.com/115670442023408995787/posts/WYPqqk2j9UB

Oder verwenden Sie direkt:

; Mouse Wheel Tab Scroll 4 Chrome
; -------------------------------
; Scroll though Chrome tabs with your mouse wheel when hovering over the tab bar.
; If the Chrome window is inactive when starting to scroll, it will be activated.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn   ; Enable warnings to assist with detecting common errors.
#SingleInstance force   ; Determines whether a script is allowed to run again when it is already running.
#UseHook Off    ; Using the keyboard hook is usually preferred for hotkeys - but here we only need the mouse hook.
#InstallMouseHook
#MaxHotkeysPerInterval 1000 ; Avoids warning messages for high speed wheel users.

SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
Menu, Tray, Tip, Mousewheel tab scroll for Chrome (1.0.3)

WheelUp::
WheelDown::
    MouseGetPos,, ypos, id
    WinGetClass, class, ahk_id %id%
    If (ypos < 45 and InStr(class,"Chrome_WidgetWin"))
    {
        IfWinNotActive ahk_id %id%
            WinActivate ahk_id %id%
        If A_ThisHotkey = WheelUp
            Send ^{PgUp}
        Else
            Send ^{PgDn}
    }
    Else
    {
        If A_ThisHotkey = WheelUp
            Send {WheelUp}
        Else
            Send {WheelDown}
    }
    Return

Ich habe keine Probleme mit Chrome / Chromium unter Ubuntu. Die von Ihnen beschriebene Funktionalität funktioniert nur für mich. Allerdings muss ich derzeit Chrome unter Windows verwenden, wo ich diese Funktionalität vermisse.

Wie einige erwähnt haben, gibt es einige Implementierungen in Skriptsprachen² wie AutoHotKey, die nur für Windows gedacht sind, und ich hatte nie das Bedürfnis, AutoHotKey, AutoIt oder eine ähnliche Software unter Linux / OSX auszuführen. aber wie ich es verstehe AutoKey und Automator gleichwertige Software sein. Daher sollte es möglich sein, das Senden grundlegender Tastenanschläge in diesen Sprachen für die spezifische Plattform erneut zu implementieren.

Hier ist die Lösung, die derzeit für mich funktioniert: AutoHotKey Community - tab_switcher - Tabs mit dem Mausrad in einem beliebigen Fenster mit Registerkarten wechseln

Hallo,

Hier ist ein weiteres Skript zum Wechseln der Tabs mit dem Mausrad - dieses Beispielskript ist für Chrome, Firefox und Internet Explorer, kann aber auch für jedes andere Programm verwendet werden.

TabJumper(psWindowClass, piStripeYStart, piStripeYEnd)
{
    WinGet, idSearchWindow, ID, ahk_class %psWindowClass%
    MouseGetPos, iMouseX, iMouseY, idHoverWindow
    if (idSearchWindow=idHoverWindow
        && iMouseY>=piStripeYStart
        && iMouseY<=piStripeYEnd ) {

        ControlFocus,, ahk_id %idHoverWindow%
        if RegExMatch(A_ThisHotkey, "i).*wheelup.*")
        {
            ControlSend, ahk_parent, {Control Down}{Shift Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Shift Up}{Control Up}, ahk_id %idHoverWindow%
        }
        else if RegExMatch(A_ThisHotkey, "i).*wheeldown.*")
        {
            ControlSend, ahk_parent, {Control Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Control Up}, ahk_id %idHoverWindow%
        }
    }
}

Anwendungsbeispiel für Chrome:

#SingleInstance, force

~WheelUp::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

~WheelDown::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

Parameter erklärt:

• TabJumper([Window class], [horizontal reaction stripe y axis start], [[horizontal reaction y axis end]])

  Was ist mit diesem "horizontalen Reaktionsstreifen"?

  Das heißt, nur in diesem Streifen eines Fensters werden Tabs umgeschaltet, der andere Teil des Fensters reagiert normal mit dem Mausrad wie zB Scrollen einer Webseite auf und ab.

Verwendung: Ja, nur die Installation von AutoHotKey und die Erstellung eines neuen.ahk Datei, das Einfügen beider Codeblöcke und das Ausführen des Skripts bringen Ihnen die Funktionalität. (Zusätzliches Markup von mir hinzugefügt.)

Um Hilfe mit dem Verständnis: {Control Down}{Shift Down}{Tab Down}und {Tab Up}{Shift Up}{Control Up}sind die Tastenanschläge, ist einer der Sequenz zum Drücken und Halten Crtl+ Shift+ Tab, die andere für sie freigegeben wird . Hier ist die Liste mit Tastaturkürzeln von Chrome.

1. Ich persönlich bevorzuge Firefox auf allen meinen Geräten gegenüber Chrom / Chrome, aber bei der Arbeit kann ein bestimmter Softwarehersteller die wichtige Browsererweiterung nicht als signierte Firefox-Erweiterung (und MS Edge) für das jeweilige Produkt veröffentlichen. In Bezug auf die Google-Desktopsoftware ist der Großteil der Software zum Zeitpunkt des Schreibens schlechter als derjenige, der mit einem Chromebook in einem Webbrowser Endgeräte bearbeitet aus meiner Sicht Einsatz erledigt.
2. Das Ausführen eines separaten Skripts für diese (grundlegende) Funktionalität ist falsch und übertrieben. Da stimme ich allen zu.

Es gibt eine einfache Chrome-Erweiterung, mit der Sie mit Alt + Mausrad nach oben / unten durch Tabs scrollen können:

https://chrome.google.com/webstore/detail/tab-wheel-scroll/aknfcgiicpmnfhncpljcadokcghjblal?hl=fr

1. Laden Sie X-Mouse Button Control herunter und installieren Sie es .
2. Öffnen Sie "Setup" aus dem Tray-Menü.
3. Fügen Sie ein neues Profil für Chrome hinzu. Beziehen Sie sich auf das Bild unten. Strings kopieren: chrome.exe, Intermediate D3D Window, Chrome_WidgetWin_1, Google Chrome Tab Scroll.
4. Wählen Sie Simulated Keysfür Wheel Up:
5. Geben Sie ein {CTRL}{PGUP}, aktivieren Sie die Option "Nur senden, wenn der Prozess des Profils aktiv ist" und drücken Sie OK.
6. Wiederholen Sie 4 für Wheel Down .
7. Wiederholen Sie 5 mit {CTRL}{PGDN} .
8. Klicken Sie auf Übernehmen.

Aaaund du bist fertig 🎉