Kann ein zugeordnetes Netzlaufwerk über die Befehlszeile erneut verbunden werden?

Täglich finde ich mich in der Windows-Eingabeaufforderung wieder, die auf ein Netzlaufwerk zugreifen muss, das zugeordnet, aber nicht verbunden ist. Ich habe noch keinen Befehl gefunden, mit dem dieses Laufwerk wieder verbunden werden kann, ohne die Zuordnung aufzuheben oder neu zuzuordnen (was zu einem Spiel zum Erraten von Passwörtern führt, da ich diese Computer nicht besitze). Ich möchte auch in der Lage sein, dies zu skripten, damit das Laufwerk jede Nacht neu verbunden wird, wenn es irgendwie getrennt wurde.

Die schnellste Lösung, die ich derzeit habe, ist:

1. Geben Sie " start." ein, um den Explorer zu öffnen.
2. Alt- Dum die Adressleiste zu fokussieren,
3. Geben Sie den gewünschten Laufwerksbuchstaben ein und drücken Sie die Eingabetaste. Warten Sie, bis der Laufwerksinhalt angezeigt wird.
4. Schließen Sie anschließend den Explorer und kehren Sie zur Eingabeaufforderung zurück.

Ich weiß, es ist eine kleine Unannehmlichkeit, aber ich mache dies oft über eine langsame VNC- oder PCAnywhere-Verbindung, bei der es schrecklich ist, irgendetwas über die GUI zu tun. Deshalb frage ich mich nur, ob es eine bessere Lösung gibt.

Vielleicht versuchen pushd \\server\share?

Ich muss Windows 7 starten, bevor ich das VPN-Programm ausführen kann, das mich mit den Netzwerklaufwerken des Unternehmens verbindet. Aus diesem Grund stellen meine Netzlaufwerke die Verbindung nicht automatisch wieder her, sondern öffnen sie nur im Windows Explorer.

Ich habe eine kleine Batch-Datei erstellt, um das VPN zu starten, die Netzlaufwerke erneut zu verbinden und einige Anwendungen zu starten, die ich immer verwende.

In meiner Batch-Datei habe ich Folgendes:

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

Der Taskkill /fi "windowtitle eq"Befehl unterscheidet zwischen Groß- und Kleinschreibung!

Erstellen Sie eine Batch-Datei (refreshletters.cmd) mit diesen Befehlen

( Diese funktionieren nur in einer Batch-Datei )

Getestet unter Win7 und XP, um die Treiberbuchstaben "Getrennt" und "Nicht verfügbar" in einem Konsolenfenster (Befehlszeile) zu aktualisieren.

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

Dies ist wahrscheinlich eine dumme Frage, aber wenn Ihr "nicht verbundenes" Laufwerk H: ist, haben Sie versucht, einfach direkt auf das Laufwerk zu wechseln?

Es funktioniert bei mir unter XPSP3:

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

Ich weiß, dass Sie gesagt haben, dass "net use" für Sie nicht funktioniert hat - aber hier ist, was Sie versuchen könnten.

Führen Sie eine Batchdatei mit der Option net use / DELETE aus, um die vorhandenen / persistenten Verbindungen zu entfernen. Anschließend können Sie net use mit der Option / SAVECRED verwenden, um die bei der letzten erfolgreichen Anmeldung verwendeten Berechtigungsnachweise für das Kennwort erneut zu verwenden. Ich bin mir nicht sicher, ob dies Ihr Problem angeht, aber es lohnt sich, es zu untersuchen.

Ich habe das gleiche Problem mit mehreren Verbindungen, und es ist zeitweise. Wenn ich den Computer neu starte, ist die Verbindung manchmal "gut" und manchmal nicht. Ich habe kein Passwortproblem, da ich in einem Firmen-LAN bin, aber ich habe immer noch den anderen Aspekt des Problems.

Ich habe eine Batch-Datei mit dem Namen ex.bat erstellt und sie (zusammen mit vielen anderen Dingen) in einem \ util-Verzeichnis gespeichert, das ich in meinen Pfad eingefügt habe. Ich kann "ex h:" eingeben und es wird Windows Explorer ausgeführt und so eingestellt, dass es direkt zum Laufwerk h: wechselt. Hier ist die Batch-Datei:

start explorer /e,/select,%1

Dies funktioniert mit viel weniger Tastenanschlägen. Wenn dies zunächst nicht funktioniert, drücken Sie die Eingabetaste, um den Ordner h: root zu öffnen und den Inhalt anzuzeigen. Oder geben Sie "ex h: \ sub" ein, in dem sich der Unterordner "sub" befindet.

Dieses Problem scheint sich in letzter Zeit erheblich verschlimmert zu haben, möglicherweise aufgrund eines der Windows XP-Sicherheitspatches.

Eine andere Sache zu versuchen ist auf der Serverseite. Auf Windows-Servern soll das Ändern eines Registrierungsschlüssels verhindern, dass der Server seine Verbindungen während einer Zeitüberschreitung trennt. Ich mache das auf so ziemlich allen unseren Servern. Die Datei ist:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

Ich hatte ein ähnliches Problem und stellte fest, dass ich eine erneute Verbindung mit einem einfachen "dir x:" über die Befehlszeile erzwingen konnte (wobei X: das zugeordnete, aber nicht verbundene Laufwerk war.). Dies war von einem Server 2003-System auf zugeordnete Laufwerke unter XP und Win7 Computers.

Ich habe die Batch-Datei wake_network_drives.bat mit den folgenden zwei Zeilen erstellt:

    dir x:
    dir z:

und legen Sie eine geplante Task fest, die jede Nacht vor dem fehlgeschlagenen Sicherungsprogramm ausgeführt wird, da die Laufwerke gelegentlich als nicht verbunden angezeigt wurden.

Tipp einfach:

NET USE H: \\server\share

(wobei H: natürlich Ihr Laufwerksbuchstabe ist)

Geben Sie 'NET /? Mit 'werden alle Optionen angezeigt, die dieser Befehl bietet.

Wenn Sie nicht dagegen sind, diese Kennwörter in einem Stapel im Klartext zu speichern, können Sie ein Skript zum Löschen und erneuten Zuordnen einschließlich Anmeldeinformationen erstellen.

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

Ich weiß, dass es nicht Ihrer Anforderung entspricht, die Freigabe nicht zu löschen, aber es löst die Wurzel des Problems, sich Kennwörter merken zu müssen.

TL; DR Zusammenfassung: Verwenden Sie net useundif exist

Beim Erstellen eines nächtlichen Backup-Skripts ist ein ähnliches Problem aufgetreten. Es musste überprüfen, ob ein Computer eingeschaltet war (mithilfe von Ping), ein Magic Packet senden, um ihn bei Bedarf einzuschalten (mithilfe von MC-WOL ), warten, bis Windows gestartet war, dann eine Verbindung zu einer SMB-Freigabe herstellen und warten präsent sein.

Während andere Antworten hier großartig sind, wollte ich nicht, dass zugeordnete Laufwerksbuchstaben ein- oder ausgeblendet werden oder dass die Verbindung zu etwas getrennt wird, mit dem der Benutzer möglicherweise arbeitet, oder dass Explorer-Fenster blinken. Ein Ziel war also keine Ablenkung durch den Benutzer .

Hier ist ein Teil des Codes, der für Sie hilfreich sein kann:

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

Wenn Sie möchten, können Sie die oben angegebene IP-Adresse durch einen Hostnamen (z server1. B. ) ersetzen .

net usewird benötigt, falls keine bestehende Verbindung besteht. Ich stieß auf einige Eckfälle, in denen es nicht ausreichend schien, die Freigabe "aufzuwecken" (z. B. wenn eine vorherige Verbindung in einem getrennten Zustand bestand). Ich fand die if existsRichtlinie hat eine ähnliche Wirkung wie die in anderen Antworten erwähnten Alternativen (wie pushd, dir, Explorerusw.), aber es schien einen leichteren Ansatz.

Die Antwort von StanZ funktionierte für mich, aber ich musste in der Lage sein, zugeordnete Laufwerke ohne den Status OK programmgesteuert zu ermitteln, da Benutzer in unserer Domäne unterschiedliche Laufwerkszuordnungen erhalten. Ich habe hier codiert, um sie als eigenständige Version auszuführen, die net usevor und nach dem eigentlichen Code ausgeführt wird, damit Sie die Ergebnisse sehen können, aber Sie müssen nur die eine FORAnweisung (drei Zeilen) in Ihren Code kopieren , um die gewünschten Ergebnisse zu erhalten.

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: https://superuser.com/questions/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: https://superuser.com/a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

Vielleicht eine alte Frage, aber immer noch relevant in 2017 und Windows 10, da Netzwerkfreigaben oft aus verschiedenen Gründen nicht richtig durch Windows verbunden oder verbunden werden. Basierend auf diesem Problem und dem Fehlen einer wirklich praktikablen und voll funktionsfähigen Lösung habe ich ein Github-Projekt erstellt, das eine Scheduler-Task und einen VBS enthält, der das Problem löst, indem einfach versucht wird, Laufwerke nach dem Fortsetzen oder Anmelden erneut zu verbinden, wenn keine Verbindung besteht oder keine Verbindung besteht.

Das Skript ist vollständig konfigurierbar und kann je nach den Bedürfnissen des tatsächlichen Benutzers eingerichtet werden.

Pfad zum Github-Projekt