Skript zum Entfernen eines USB-Laufwerks vor dem Abmelden

Ich lasse meine USB-Laufwerke immer an die Labormaschinen meiner Abteilung angeschlossen. Bisher hatte ich das Glück, sie immer im Fundbüro zu finden, aber sie nicht zu haben, wenn Sie sie brauchen, wird ein bisschen ärgerlich.

Gibt es ein Dienstprogramm / Skript, das mich auffordert, es zu entfernen, bevor ich mich abmelde?
Ich suche nach einer Lösung, um dies sowohl unter Windows als auch unter Linux zu tun.
Gibt es Hinweise, wie man einen schreibt?

Ein einfaches VBScript zur Überprüfung des Vorhandenseins von Wechseldatenträgern sieht folgendermaßen aus:

boolDeviceFound = False
strComputer = InputBox("Enter the name of the computer to search for USB devices:")
strComputer = Trim(strComputer)
If LenB(strComputer) = 0 Then
    strComputer = "."
End If

'Query the WMI service for the computer name
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

'Display the connected computer
WScript.Echo "You have successfully connected to computer " & strComputer

Set colItems = objWMIService.ExecQuery("SELECT * from Win32_LogicalDisk WHERE Description = 'Removable Disk'")
For Each objItem in colItems
    WScript.Echo "The computer " & strComputer & " has a removable USB drive connected with drive letter: " & objItem.Name
    WScript.Echo "Please remove this device from " & strComputer & " to comply with Lab policies!"
    boolDeviceFound = True
Next

If boolDeviceFound = False Then
    WScript.Echo "No USB devices found!"
End If

Wenn Sie es als etwas wie DetectUSB.vbs speichern , kann es über die Befehlszeile oder eine Batch-Datei mit ausgeführt werden wscript DetectUSB.vbs. Ähnliches kann auch mit PowerShell geschrieben werden, und das Batchdatei / PS-Skript kann als Abmeldeskript festgelegt werden . Das einzige Problem ist, haben Sie überhaupt ausreichende Rechte auf den Labor-PCs, um Abmeldeskripte zu installieren?