Wie kann man eine Excel-Datei (.xlsx), die mehrere Arbeitsblätter enthält, in separate Arbeitsblätter [n] .xlsx aufteilen?

Ich denke, der Titel sagt schon alles für diese Frage aus, aber um es ein bisschen weiter auszuführen:

Ich habe eine XLSX-Datei, die ein paar Dutzend Blätter enthält. Ich möchte alle diese Blätter als separate XLSX-Dateien ausgeben. Eine automatische Benennung ist nicht erforderlich. Hat Excel eine Funktion, um Blätter in eine separate Datei zu exportieren?

Es ist keine eingebaute Funktion.

Wenn Sie diesen Code jedoch ausführen, sollte er den Job erledigen.

Sub SaveSheets()
    Dim strPath As String
    Dim ws As Worksheet

    Application.ScreenUpdating = False

    strPath = ActiveWorkbook.Path & "\"
    For Each ws In ThisWorkbook.Sheets
        ws.Copy
        'Use this line if you want to break any links:
        BreakLinks Workbooks(Workbooks.Count)
        Workbooks(Workbooks.Count).Close True, strPath & ws.Name & ".xlsx"
    Next

    Application.ScreenUpdating = True
End Sub

Sub BreakLinks(wb As Workbook)
    Dim lnk As Variant
    For Each lnk In wb.LinkSources(xlExcelLinks)
        wb.BreakLink lnk, xlLinkTypeExcelLinks
    Next
End Sub

Führen Sie die folgenden Schritte aus, um den Code auszuführen:

1. Öffnen Sie den VBA-Editor ( Alt+ F11)
2. Klicken Sie in der Baumstruktur oben links mit der rechten Maustaste auf Ihre Arbeitsmappe und fügen Sie ein neues Modul ein
3. Kopieren Sie den obigen Code in dieses Modul
4. Schließen Sie den VBA-Editor
5. Drücken Sie in Excel Alt+ F8, um Makros auszuführen, und wählen Sie ausSaveSheets

oder siehe Wie füge ich VBA in MS Office hinzu?

1. Wenn Sie mit der rechten Maustaste auf die Registerkarte einer Excel-Tabelle klicken, können Sie Verschieben oder Kopieren auswählen.

   

2. Im daraufhin angezeigten Dialogfeld können Sie eine Zielarbeitsmappe auswählen. Wählen Sie (neues Buch) .

   

3. Klicken Sie auf OK . Ihr Blatt befindet sich jetzt in einem neuen Dokument.

Ich habe Peter Alberts Lösung ausprobiert und es hat bei mir nicht funktioniert. Deshalb habe ich in diesem Beitrag („Excel - Arbeitsblätter als separate Dateien speichern“) bei Diary eines Computerfreaks eine Lösung gefunden .

Es funktioniert super Sie sollten Blätter, die Punkte enthalten, umbenennen, um korrekt benannte Dateien mit .xlsErweiterungen zu erhalten.

Sub CreateNewWBS()
Dim wbThis As Workbook
Dim wbNew As Workbook
Dim ws As Worksheet
Dim strFilename As String

    Set wbThis = ThisWorkbook
    For Each ws In wbThis.Worksheets
        strFilename = wbThis.Path & "/" & ws.Name
        ws.Copy
        Set wbNew = ActiveWorkbook
        wbNew.SaveAs strFilename
        wbNew.Close
    Next ws
End Sub

Verwenden Sie die Anweisungen zum Erstellen und Ausführen dieses Makros aus dem Post von Peter Albert oder aus Wie füge ich VBA in MS Office hinzu?