Wie berechne ich die Anzahl der Monate zwischen zwei Daten in Excel? [Duplikat]

8

Ich habe zwei Spalten in Microsoft Excel: F ist die Spalte mit dem Datum, an dem der Dienst beendet wurde. E ist die Spalte mit dem Datum, an dem der Dienst begonnen hat.

Wie berechne und melde ich die Anzahl der Monate für jede Person?

microsoft-excel Terrance Drake
quelle
Bitte teilen Sie uns das gewünschte Ergebnis mit (zB) 14.3.2014 - 12.7.2014: (a) 4 Monate (der 4. ist nicht vollständig) oder (b) 5 Monate (jeden berührten Monat zählen) oder (c) 3 Monate (nur) vollständige Monatszählung) oder (d) 3,9 Monate.
Guntbert
1
Antwort hier ist besser als "Original" in dieser Frage verlinkt
Jayan

Antworten:

16

Die DATEDIF-Funktion gibt explizit die Anzahl der Monate zwischen zwei Daten an - sie rundet ab

=DATEDIF(A2,B2,"m")

Dabei ist A2 das frühere der beiden Daten

Wenn Sie auf den "nächsten" ganzen Monat runden möchten, können Sie diese Version verwenden

=DATEDIF(A2,B2+15,"m")

Wenn Sie sich nicht für den Tag interessieren und ein Datum im Januar bis zu einem Datum im März 3 Monate beträgt, können Sie diese Version verwenden

=DATEDIF(A2-DAY(A2)+1,B2,"m")+1

Barry Houdini
quelle
Funktioniert auch mit Google Sheets.
Adriano P
Sie können verwenden, =(B2 - A1)/(365/12)wenn Sie eine nicht gerundete Antwort wünschen, es wird angenommen, dass ein Monat durchschnittlich 365/12 Tage lang ist
aljgom
3

Es gibt eine KB von Microsoft, die genau dieses Thema hier behandelt

Es bietet zwei Lösungen, je nachdem, ob Sie die Monate abrunden oder aufrunden möchten.

Zusammenfassen:

=(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

Abrunden:

=IF(DAY(LDate)>=DAY(EDate),0,-1)+(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

In beiden Fällen ist EDate die Zelle, die das frühere Datum enthält, und LDate ist die Zelle, die das spätere Datum enthält.

kenkh
quelle