Tastaturkürzel zum Wechseln zwischen Arbeitsblättern in Excel

Antworten:

20

Ctrl+ PgUpum nach links zu gehen.

Ctrl+ PgDnnach rechts bewegen.

Dmatig
quelle
Dies gilt auch für Excel 2013 =)
Metafaniel
und auf einem macbook ohne pgup und pgdown?
Theonlygusti
Ich wünschte, sie hätten eine bessere Abkürzung, da die Page Upund Page Downin verschiedenen Laptops immer schwer zu finden sind und nicht sehr bequem auf der Tastatur platziert werden.
Cricrazy
3

VBA-Makros und benutzerdefinierte Tastenkombination zum Aktivieren des ersten oder letzten Blatts

Wenn eine tatsächliche Tastenkombination zum ersten oder letzten Arbeitsblatt springen soll, fügen Sie diesen Code in ein Modul in der Arbeitsmappe "PERSÖNLICH" ein:

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Gehen Sie zur Registerkarte Entwickler> Makros. Wechseln Sie zu diesen Makros (ToFirstSheet und ToLastSheet). Wählen Sie eine aus, klicken Sie auf Optionen und weisen Sie eine Tastenkombination zu. Mach dasselbe für den anderen.

Durch Speichern in der Arbeitsmappe "PERSÖNLICH" ist diese in jeder Excel-Datei verfügbar.

Eingebaute Tastaturkürzel zum Aktivieren des vorherigen oder nächsten Blatts

Mit den folgenden Standardtastenkombinationen können Sie ein Arbeitsblatt nach links oder rechts springen:

Ctrl+PgUp

Ctrl+PgDn

VBA-Makros zum Aktivieren des vorherigen oder nächsten Blatts

Gehen Sie wie folgt vor, um dasselbe mit VBA zu erreichen:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

VBA-Funktionen zum Zurückgeben des vorherigen oder nächsten Blatts

Verwenden Sie diese Funktion, wenn Sie lieber das vorherige oder nächste Arbeitsblattobjekt erhalten möchten:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Verwenden Sie die Funktionen wie folgt:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub
ChrisB
quelle
Wie komme ich zum nächsten und vorherigen Blatt? Ich möchte ein Sub ToPreviousSheetund machen ToNextSheet?
Theonlygusti
Verwenden Sie dazu den Blattindex. Ich werde meine Antwort aktualisieren, um dies einzuschließen.
ChrisB
1

Sie können auch die Zugriffstasten verwenden, um zum GoDialogfeld zu gelangen . Sie können dann etwas eingeben foo!A1, um zur oberen linken Zelle im Blatt mit dem Namen "foo" zu navigieren. Während Bild auf und Bild ab sind in der Regel schneller. Wenn Sie eine große Anzahl (z. B. 20+) gut benannter Blätter haben, ist dies möglicherweise schneller. Go funktioniert auch gut, wenn Sie Tabellen in Ihren Blättern benannt haben.

Durch Drücken von F5 wird normalerweise das GoDialogfeld geöffnet .

Jeromy Anglim
quelle