Ich möchte in der Lage sein, Titel, Autor, Jahr ohne Klammern zu erhalten.
Im Folgenden wird gezeigt, wie Sie einen benutzerdefinierten Basisbibliografiestil in Word erstellen. Der Link enthält auch Anweisungen zum Erstellen komplexerer Stile.
Erstellen Sie benutzerdefinierte Bibliographiestile
Erstellen Sie zunächst einen grundlegenden Bibliographiestil, dem der benutzerdefinierte Stil folgt. Richten Sie den Bibliographiestil ein
Um einen Bibliographiestil zu erstellen, erstellen wir ein XML-Stylesheet. Dies ist eine .xslDatei MyBookStyle.xsl, die mit Ihrem bevorzugten XML-Editor aufgerufen wird. Notepadwird gut tun. Wie der Name schon sagt, wird unser Beispiel ein Stil für einen "Buch" -Quellentyp sein.
Fügen Sie am Anfang der Datei den folgenden Code hinzu:
<?xml version="1.0" ?>
<!--List of the external resources that we are referencing-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:b="http://schemas.openxmlformats.org/officeDocument/2006/bibliography">
<!--When the bibliography or citation is in your document, it's just HTML-->
<xsl:output method="html" encoding="us-ascii"/>
<!--Match the root element, and dispatch to its children-->
<xsl:template match="/">
<xsl:apply-templates select="*" />
</xsl:template>
Wie aus den Kommentaren hervorgeht, verwendet Word HTML, um eine Bibliographie oder ein Zitat in einem Dokument darzustellen. Der größte Teil des vorangegangenen XML-Codes dient lediglich der Vorbereitung auf die interessanteren Teile des Stils. Sie können Ihrem Stil beispielsweise eine Versionsnummer zuweisen, um die vorgenommenen Änderungen zu verfolgen, wie im folgenden Beispiel gezeigt.
<!--Set an optional version number for this style-->
<xsl:template match="b:version">
<xsl:text>2006.5.07</xsl:text>
</xsl:template>
Noch wichtiger ist, dass Sie Ihrem Stil einen Namen geben können. Diesen tag: <xsl:when test="b:StyleNameLocalized">; Geben Sie Ihrem Stil einen Namen in der Sprache Ihrer Wahl, indem Sie den folgenden Code verwenden.
<xsl:when test="b:StyleNameLocalized/b:Lcid='1033'">
<xsl:text>[Your Style Name]</xsl:text>
</xsl:when>
Dieser Abschnitt enthält den Gebietsschemanamen Ihres Stils. In unserer Beispieldatei soll der Name unseres benutzerdefinierten Bibliografiestils "Einfacher Buchstil" in der Dropdown-Liste "Stil" auf der Registerkarte "Verweise" angezeigt werden. Fügen Sie dazu den folgenden XML-Code hinzu, um diesen Stil anzugeben Name in der englischen Sprache sein (Lcid bestimmt die Sprache).
<!--Defines the name of the style in the References dropdown list-->
<xsl:when test="b:StyleNameLocalized">
<xsl:choose>
<xsl:when test="b:StyleNameLocalized/b:Lcid='1033'">
<xsl:text>Simple Book Style</xsl:text>
</xsl:when>
</xsl:when>
Ihr Stil wird nun unter einem eigenen Namen im Dropdown-Listenfeld Bibliografiestil in der Anwendung angezeigt.
Untersuchen Sie nun die Stildetails. Jeder Quellentyp in Word (z. B. Buch, Film, Artikel in einer Zeitschrift usw.) verfügt über eine integrierte Liste von Feldern, die Sie für die Bibliografie verwenden können. Um alle für einen bestimmten Quellentyp verfügbaren Felder anzuzeigen, wählen Sie auf der Registerkarte "Verweise" die Option "Quellen verwalten" und anschließend im Dialogfeld "Quellen-Manager" die Option "Neu", um das Dialogfeld "Quelle erstellen" zu öffnen. Wählen Sie dann Alle Bibliographiefelder anzeigen.
Für einen Buchquellentyp stehen folgende Felder zur Verfügung:
- Autor
- Titel
- Jahr
- Stadt
- Bundesstaat / Provinz
- Land / Region
- Verleger
- Editor
- Volumen
- Anzahl der Bände
- Übersetzer
- Kurzer Titel
- Standardnummer
- Seiten
- Auflage
- Bemerkungen
Im Code können Sie die Felder angeben, die für Ihren Bibliographiestil wichtig sind. Auch wenn die Option Alle Literaturfelder anzeigen deaktiviert ist, werden diese Felder angezeigt und mit einem roten Sternchen versehen. In unserem Buchbeispiel möchte ich sicherstellen, dass der Autor, der Titel, das Jahr, der Ort und der Verlag eingegeben werden. Daher soll neben diesen Feldern ein rotes Sternchen angezeigt werden, um den Benutzer darauf hinzuweisen, dass es sich um empfohlene Felder handelt, die ausgefüllt werden sollten .
<!--Specifies which fields should appear in the Create Source dialog box when in a collapsed state (The Show All Bibliography Fields check box is cleared)-->
<xsl:template match="b:GetImportantFields[b:SourceType = 'Book']">
<b:ImportantFields>
<b:ImportantField>
<xsl:text>b:Author/b:Author/b:NameList</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Title</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Year</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:City</xsl:text>
</b:ImportantField>
<b:ImportantField>
<xsl:text>b:Publisher</xsl:text>
</b:ImportantField>
</b:ImportantFields>
</xsl:template>
Der Text in den <xsl:text>Tags verweist auf die Sources.xmlDatei. Mit diesen Verweisen werden die Daten abgerufen, mit denen die einzelnen Felder gefüllt werden. Untersuchen Sie Sources.xml( %APPDATA%\Microsoft\Bibliography\Sources.xml), um eine bessere Vorstellung davon zu erhalten, wie diese Verweise mit denen in der XML-Datei übereinstimmen.
Gestalten Sie das Layout
Die Ausgabe für Bibliografien und Zitate wird in einem Word-Dokument als HTML dargestellt. Um zu definieren, wie unsere benutzerdefinierten Bibliografie- und Zitierstile in Word aussehen sollen, müssen wir unserem Stylesheet HTML-Code hinzufügen.
Angenommen, Sie möchten jeden Eintrag in Ihrem Literaturverzeichnis folgendermaßen formatieren:
Last Name, First Name. (Year). Title. City: Publisher
Der dazu erforderliche HTML-Code wird wie folgt in Ihr Stylesheet eingebettet.
<!--Defines the output format for a simple Book (in the Bibliography) with important fields defined-->
<xsl:template match="b:Source[b:SourceType = 'Book']">
<!--Label the paragraph as an Office Bibliography paragraph-->
<p>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:Last"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:First"/>
<xsl:text>. (</xsl:text>
<xsl:value-of select="b:Year"/>
<xsl:text>). </xsl:text>
<i>
<xsl:value-of select="b:Title"/>
<xsl:text>. </xsl:text>
</i>
<xsl:value-of select="b:City"/>
<xsl:text>: </xsl:text>
<xsl:value-of select="b:Publisher"/>
<xsl:text>.</xsl:text>
</p>
</xsl:template>
Wenn Sie in Ihrem Word-Dokument auf eine Buchquelle verweisen, muss Word auf diesen HTML-Code zugreifen, damit er den benutzerdefinierten Stil zum Anzeigen der Quelle verwenden kann. Sie müssen also Ihrem benutzerdefinierten Stylesheet Code hinzufügen, damit Word dies ausführen kann.
<!--Defines the output of the entire Bibliography-->
<xsl:template match="b:Bibliography">
<html xmlns="http://www.w3.org/TR/REC-html40">
<body>
<xsl:apply-templates select ="b:Source[b:SourceType = 'Book']">
</xsl:apply-templates>
</body>
</html>
</xsl:template>
In ähnlicher Weise müssen Sie dasselbe für die Zitierausgabe tun. Folgen Sie dem Muster (Autor, Jahr) für eine einzelne Zitierung im Dokument.
<!--Defines the output of the Citation-->
<xsl:template match="b:Citation/b:Source[b:SourceType = 'Book']">
<html xmlns="http://www.w3.org/TR/REC-html40">
<body>
<!-- Defines the output format as (Author, Year)-->
<xsl:text>(</xsl:text>
<xsl:value-of select="b:Author/b:Author/b:NameList/b:Person/b:Last"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="b:Year"/>
<xsl:text>)</xsl:text>
</body>
</html>
</xsl:template>
Schließen Sie die Datei mit den folgenden Zeilen.
<xsl:template match="text()" /> </xsl:stylesheet>
Speichern Sie die Datei als MyBookStyle.XSLund legen Sie sie im Styles-Verzeichnis ab ( %appdata%\Microsoft\Bibliography\Style). Starten Sie Word neu, und Ihr Stil befindet sich jetzt in der Dropdown-Liste "Stil". Sie können Ihren neuen Stil verwenden.
Quelle Benutzerdefinierte Bibliografie-Stile erstellen
