Vervollständigung der Registerkarte zsh in leerer Zeile

Ich hätte gerne einen Tcsh'ism, den ich nicht finden konnte: In einer leeren Zeile ohne Inhalt möchte ich die Tabulatortaste drücken und das Äquivalent eines ls sehen. Das heißt, ich will

$ <tab>

etwas anderes zu tun, als mir ein \ t zu geben. Ich habe fantastische Ressourcen für die Befehlsvervollständigung gefunden, aber nicht für diesen Basisfall. Jede Hilfe dazu wäre toll! Vielen Dank.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Das Verhalten Tabam Zeilenanfang wird durch den Stil gesteuert . Es gibt jedoch nur zwei unterstützte Verhaltensweisen:insert-tab

• Fertigstellung wie gewohnt unter zstyle ':completion:*' insert-tab false
• Fügen Sie eine Registerkarte unter ein zstyle ':completion:*' insert-tab true
• entweder der eine oder der andere unter zstyle ':completion:*' insert-tab pending[=N]

Wenn Sie nur Befehle an dieser Position ausführen möchten, reicht zstyle ':completion:*' insert-tab truedies aus. Wenn Sie etwas anderes möchten, z. B. das Auflisten der Dateien im aktuellen Verzeichnis, müssen Sie Änderungen vornehmen _main_complete.

Ein aktueller Thread auf der Zsh-Worker-Liste wurde diskutiert insert-tab.

Hier ist die vollständige Implementierung der Autoliste von tcsh in zsh, wenn Sie in einer leeren Zeile die Tabulatortaste drücken

% <TAB>

Hier ist es:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Wenn Sie tcsh genauer emulieren möchten, fügen Sie dies auch Ihrer .zshrc hinzu:

unsetopt always_last_prompt       # print completion suggestions above prompt

Ich habe dieses zsh-Widget geschrieben, das die Verwendung von TAB verbessert, nicht nur in einer leeren Zeile, sondern auch während Sie einen Befehl eingeben.

• Es listet Dateien in einer leeren Befehlszeile und in der Mitte eines Befehls auf.
• Es listet Verzeichnisse auf auf einem leeren Befehlszeile.
• Es werden ausführbare Dateien in einer leeren Befehlszeile aufgelistet.

Es kann so konfiguriert werden, dass "cd" oder "./" in diesen Fällen einer globalen Variablen vorangestellt wird.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA