Zuordnung, um das Symbol unter dem Cursor mit einem Ausdruck einzuschließen, der das Symbol enthält

Ich habe eine Stunde lang vim-Skriptbeiträge gelesen, aber ich fürchte, ich habe nicht die Fähigkeiten, diese Beiträge auf mein Problem anzuwenden. Beim Bearbeiten von Mathematik in Latexdokumenten möchte ich häufig mathematische Symbole wie +, -, = durch \ Pad {+}, \ Pad {-}, \ Pad {=} ersetzen, wobei \ Pad ein Latexmakro I 'ist. ve definiert, um Platz um das Symbol zu setzen. Ich möchte meinen Cursor auf ein solches Symbol setzen, ein paar Buchstaben eingeben, sagen ;Pund diese Aktion das Symbol durch ersetzen lassen

\Pad{whatever the symbol under the cursor is}

Jede Hilfe wäre sehr dankbar!

`

function! s:PadMacro(type) abort
    if a:type ==# 'char'
        normal! `[v`]d
    elseif a:type ==# 'line'
        normal! '[V']d
    elseif a:type ==# 'v'
        normal! `<v`>d
    else
        return
    endif
    let string = '\Pad{' . @" . '}'
    silent execute "normal! i\<c-r>=string\r"
endfunction
nnoremap <silent> ;P :set operatorfunc=<sid>PadMacro<cr>g@
vnoremap <silent> ;P :<c-u>call <sid>PadMacro(visualmode())<cr>

Wenn Sie den vorherigen Code in Ihr vimrc einfügen, sollte es tun, was Sie wollen.

Um es zu verwenden, drücken Sie ;P{motion}und die PadMacro()Funktion sollte die {motion}mit \Pad{und abgedeckten Zeichen einschließen }.

Anwendungsbeispiele:

• ;Plum das Zeichen unter dem Cursor einzuschließen (da les sich um eine Bewegung handelt, die das Zeichen unter dem Cursor abdeckt)
• ;Piwum das Wort unter dem Cursor einzuschließen (da iwes sich um ein Textobjekt handelt, das alle Zeichen innerhalb des Wortes unter dem Cursor abdeckt)
• ;Pisum den Satz einzuschließen, in dem sich der Cursor befindet (weil ises sich um ein Textobjekt handelt, das alle Zeichen in einem Satz abdeckt)
• ;P$ um die Zeichen zwischen Ihrem Cursor und dem Ende der Zeile einzuschließen
• ;P um die visuell ausgewählten Zeichen einzuschließen

Alles, was von der PadMacro()Funktion ausgeführt wird, wird als einzelne Ausgabe betrachtet, was bedeutet, dass der Punkt wiederholbar ist.
Mit anderen Worten, wenn Sie mehrere ähnliche Textteile einschließen \Pad{}müssen, müssen Sie die Zuordnung nicht jedes Mal, sondern nur beim ersten Mal treffen (danach können Sie drücken ., um Ihre letzte Ausgabe zu wiederholen).

Eine vollständige Liste der Textobjekte, auf die Sie Ihr Gehäuse anwenden können, finden Sie unter :
:help text-objects.

Die Idee ist einfach:

1. Sie schneiden den Text, den Sie umgeben möchten, und wechseln in den Einfügemodus.
2. Sie fügen den ersten Teil ein,
3. Sie fügen den Inhalt des unbenannten Registers ein.
4. Sie fügen den letzten Teil ein,
5. Sie verlassen den Einfügemodus.

Für Ihr Beispiel würden Sie tun:

s\Pad{<C-r>"}<Esc>

Welches kann für Ihre Bequemlichkeit abgebildet werden:

" normal mode, for single characters
nnoremap ;P s\Pad{<C-r>"}<Esc>

" visual mode, for multiple characters
xnoremap ;P s\Pad{<C-r>"}<Esc>

Beachten Sie, dass es möglich ist, ein anderes Register zu verwenden, wenn Sie das unbenannte Register nicht überladen möchten. Hier benutze ich das zRegister:

"zs\Pad{<C-r>z}<Esc>

Nur noch eine Lösung für den Fall, dass Surround nicht nur ein Symbol enthält (Beispiel aus meiner Konfiguration für Surround mit "[" & "]"

vmap Q[ O<Esc>i[<Esc>gvo<Esc>la]<Esc>
nnoremap Q[ veO<Esc>i[<Esc>gvo<Esc>la]<Esc>

Der Schlüssel ist, "o" & "O" zu verwenden, um zum Anfang / Ende der Auswahl zu gelangen