Verketten Sie mehrere Spalten in Google Sheets zu einer

15

Geben Sie hier die Bildbeschreibung ein

Ich möchte die Spalten A, B und C wie angezeigt in Spalte D verketten / kombinieren.

Die Anzahl der ausgefüllten Einträge in A, B und C variiert im Laufe der Zeit, sodass absolute Zellenadressen nicht verwendet werden können.

Welche Formel könnte ich in D1 einfügen, um die Spalte wie abgebildet zu füllen?

google-sheets concatenate Paulb
quelle
Mir ist bewusst, dass "Anhängen" möglicherweise ein besserer Wortschatz als "Verketten" war. Da Verketten etwas ist, was Sie normalerweise mit einzelnen Werten tun.
Paulb
1
Vielleicht die beste Antwort zum Zusammenführen für statistische Manipulationen hier, wo Sie hier nicht filtern müssen webapps.stackexchange.com/a/69049/66725 Verwenden Sie also einfach = {A1:A; B1:B}. Usw., um eindeutige Übereinstimmungen in zwei Spalten zu zählen = count(unique(A1:A; B1:B})).
Léo Léopold Hertz 준영

Antworten:

9

Sie müssen nach nicht leeren Zellen filtern und dann die Ergebnisse stapeln:

={filter(A:A, len(A:A)); filter(B:B, len(B:B)); filter(C:C, len(C:C))}

Dies ist das gleiche wie diese Antwort von Grayob, die leider unter veralteten Antworten begraben ist.

user79865
quelle
1
Hat perfekt funktioniert. Ich sah, dass Q und ich uns erfolglos auf die Vmerge konzentrierten. In diesem Q ist die Antwort von Grayob besser als die akzeptierte Antwort. Tks.
Paulb
13

Eine kürzere Version der Formel in dieser anderen Antwort

=FILTER({A:A;B:B;C:C}, LEN({A:A;B:B;C:C}))
Rubén
quelle
2

Etwas länger, kann aber auf ein begrenztes Array (nicht ganze Spalten) beschränkt werden:

=transpose(split(textjoin("|",1,{A1:C4}),"|"))

wo die Reihenfolge keine Rolle spielt. Wo es tut:

=transpose(split(textjoin("|",1,{A1:A4;B1:B4;C1:C4}),"|"))
pnuts
quelle
Dies ist meine Lieblingslösung für dieses Problem. Es müssen nicht alle Spalten benannt werden. Sie können auch SORTIEREN für die erste Lösung, bei der die Alphabetisierung erfolgen soll.
Lou